build.gradle

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: 'maven'


repositories {
    mavenCentral()
}

signing {
    sign configurations.archives
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

javadoc {
    options.encoding = 'UTF-8'
}

artifacts {
    archives sourcesJar
    archives javadocJar
}


group = 'io.yggdrash'
version = '0.10.0-beta'


ext {
    grpcVersion         = '1.20.0'
    protobufVersion     = '3.7.1'
    levelDBVersion      = '0.11'
    ehcacheVersion      = '3.7.1'
    scastleVersion      = '1.58.0.0'
    commonsCodecVersion = '1.11'
    commonsIOVersion    = '2.6'
    gsonVersion         = '2.8.5'
    jsonSimpleVersion   = '1.1'
    jacksonVersion      = '2.9.8'
    typesafeVersion     = '1.3.3'
    logbackVersion      = '1.2.3'
    annotationVersion   = '1.3.2'
    assertjVersion      = '3.11.1'
    commonLangVersion   = '3.8.1'
    collectionsVersion  = '4.2'
    logbackEsAppenderVersion  = '1.6'
    logbackJinoVersion  = '3.0.12'
    equinoxVersion = '3.13.0.v20180226-1711'
    set('elasticsearch.version', '7.0.1')
}


dependencies {
    compile "io.yggdrash:contract-core:0.10.0-beta"
    compile "ch.qos.logback:logback-classic:${logbackVersion}"
    compile "org.iq80.leveldb:leveldb:${levelDBVersion}"
    compile "com.madgag.spongycastle:prov:${scastleVersion}" // for SHA3 and SECP256K1
    compile "commons-io:commons-io:${commonsIOVersion}"
    compile "commons-codec:commons-codec:${commonsCodecVersion}"
    compile "org.apache.commons:commons-lang3:${commonLangVersion}"
    compile "org.apache.commons:commons-collections4:${collectionsVersion}"

    testCompile "org.assertj:assertj-core:${assertjVersion}"
    testCompile "com.vmlens:concurrent-junit:1.0.2"
}

uploadArchives {
    repositories {
        mavenDeployer {

            // Sign POM
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            // Destination
            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }
            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            // Add required metadata to POM
            pom.project {
                name 'Yggdrash Common Library'
                packaging 'jar'
                description 'Yggdrash Common Library'
                url 'https://yggdrash.io'

                scm {
                    connection 'scm:git:git://github.com/yggdrash/common.git'
                    developerConnection 'scm:git:ssh://github.com/yggdrash/common.git'
                    url 'https://github.com/yggdrash/common/tree/master'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'yggdrash'
                        name 'YGGDRASH DEVELOP TEAM'
                        email 'dev@yggdrash.io'
                        organization 'yggdrash'
                        organizationUrl 'http://yggdrash.io'
                    }
                }
            }
        }
    }
}