build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
  id "com.github.hierynomus.license" version "0.14.0"
  id "com.xebialabs.xldp" version "1.0.5"
  id 'nebula.release' version '15.2.0'
  id "com.xebialabs.xl.docker" version "1.1.0"
  id "com.github.hierynomus.jython" version "0.11.0"
}

apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'java'
apply plugin: 'maven'


repositories {
  mavenLocal()
  mavenCentral()
  maven {
    url 'https://dist.xebialabs.com/public/maven2'
  }
}

def apiVersion = "2019.3.7"
sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
  compile "com.xebialabs.deployit:udm-plugin-api:$apiVersion"
  compile 'com.google.guava:guava:18.0'
  compile "junit:junit:4.11"

  // https://mvnrepository.com/artifact/org.eclipse.mylyn.github/org.eclipse.egit.github.core
  compile group: 'org.eclipse.mylyn.github', name: 'org.eclipse.egit.github.core', version: '2.1.5'
  distBundle group: 'org.eclipse.mylyn.github', name: 'org.eclipse.egit.github.core', version: '2.1.5'


  jython ":requests:2.19.1"
  jython ":certifi:2019.9.11"

  jython python("urllib3:urllib3:1.23") {
    copy {
      from "urllib3"
    }
  }


  jython python(":six:1.15.0") {
    useModuleName = false // Copy not to moduleName 'six', but rather to the root
    copy {
      from "six.py" // Will only copy six.py
    }
  }

  jython "chardet:chardet:3.0.4"

  runtime group: 'org.python', name: 'jython-standalone', version: '2.7.0'

}

tasks.withType(org.gradle.api.tasks.testing.Test) {
  //systemProperty 'GithubClientTest.token', GithubClientTestToken
  systemProperties['GithubClientTest.token'] = System.getProperty("GithubClientTestToken")
}

processResources.configure {
  from 'src/main/config'
  filter ReplaceTokens, tokens: [
    'project.version': version.toString(),
    'project.name'   : rootProject.name
  ]
}

license {
  header rootProject.file('License.md')
  strictCheck true
  ext.year = Calendar.getInstance().get(Calendar.YEAR)
  ext.name = 'XEBIALABS'
  excludes(["six.py", "**/requests/**/*.py", "**/idna/**/*.py", "**/certifi/**/*.py", "**/urllib3/**/*.py", "**/jwt/**/*.py", "**/chardet/**/*.py", "**/github/**/*.*"])
}