Create helper for max size, as bounded by Limit

[arnetheduck]

Many types like Attestation have a useful max serialized size that can be computed by using the Limit of every List as upper bound - a helper to compute this value would be generally useful for example to harden the decompression code against overlong messages: status-im/nimbus-eth2#3230 (comment)

[arnetheduck]

import
  std/typetraits,
  ../beacon_chain/spec/eth2_ssz_serialization,
  ../beacon_chain/spec/datatypes/[deneb]

proc maxSize(T: type): int =
  when isFixedSize(T):
    fixedPortionSize(T)
  elif T is HashList:
    maxSize(T.T)
  elif T is BitList:
    (T.maxLen div 8) + 1
  elif T is BitArray:
    (T.maxLen + 7) div 8
  elif T is List:
    type E = T.T
    when isFixedSize(E):
      T.maxLen * maxSize(E)
    else:
      T.maxLen * (maxSize(E) + 4)

  elif T is object|tuple:
    var size = fixedPortionSize(T)
    for field in fields(default(T)):
      when not isFixedSize(typeof(field)):
        size += maxSize(typeof(field))
    size
  else:
    0

proc printSizes(T: type, indent: string) =
  when T is object:
    for name, field in fieldPairs(default(T)):
      type F = typeof(field)
      echo indent, name, ": ", maxSize(F)

      when not isFixedSize(F):
        printSizes(F, indent & "  ")

proc printSizes(T: type) =
  echo T.name, ": ", maxSize(T)
  printSizes(T, "  ")

printSizes(deneb.SignedBeaconBlock)
printSizes(Attestation)

a humble beginning that gets us as far as the deneb block I think