forked from aviatorRHK/rpiForth
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathrForthCore.s
5246 lines (4741 loc) · 141 KB
/
rForthCore.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*************************************************************************
*
* rForth is developed by Roland Koluvek.
* Start date January 27, 2012
* ARM forth system
* Define the Forth engine
* ARM registers defined here.
* 20130115 Project restarted on a Raspberry Pi
* 20130309 moved return stack and parameter stack per memory map .sp0;.rp0
* 20130310 __CODE instead of __COLON for the word CHAR.
* 20130320 repair DOES>. and MARKER
**************************************************************************/
.global rForthCore
.code 32
@ r0 to r9 are general work registers
w .req r10 @ Forth work register
rsp .req r11 @ Return Stack Pointer
@ IP .req r12 @ Interpreter Pointer @ predefined
@ SP .req r13 @ @ SP predefined
@ LR .req r14 @ Link Register
@ PC .req r15 @ Program Counter
/* Basic types */
.equ normal, 0x00
.equ compile_only, 0x40
.equ immediate, 0x80
/* ---- Basic Macros Defined here ---- */
@ pushr -- push a register data (reg1) on to a stack ptr to by reg2.
.macro pushr,reg1,reg2
str \reg1,[\reg2,#-4]!
.endm
@ popr -- pop a register data (reg1) from a stack ptr to by reg2.
.macro popr,reg1,reg2
ldr \reg1,[\reg2],#4
.endm
@ pickr n words down from reg2 stack and reg1
@ holds ncells which becomes the poped item,
.macro pickr reg1,reg2
ldr \reg1,[\reg2,\reg1,lsl #2]
.endm
@ LABEL set up a global label
.macro label lblName
.global \lblName
\lblName:
.endm
@ HEADER for code Builds a head for Forth defintions
.macro __CORE fncName,lenx,assmName,type=0
.align 2
.word link
.set link, .-4
.hword view
.set view, view + 1
.byte \lenx + \type
.ascii "\fncName"
.align 2, 0x20
.global \assmName
\assmName:
.endm
@ CODE HEADER Builds a header for code definition
.macro __CODE fncName,lenx,assmName,type=0
.align 2
.word link
.set link, .-4
.hword view
.set view, view + 1
.byte \lenx + \type
.ascii "\fncName"
.align 2, 0x20
.global \assmName
\assmName:
.word . + 4
.endm
@ COLON HEADER Builds a header for colon definition
.macro __COLON fncName,lenx,assmName,type=0
.align 2
.word link
.set link, .-4
.hword view
.set view, view + 1
.byte \lenx + \type
.ascii "\fncName"
.align 2, 0x20
.global \assmName
\assmName:
.word _nest
.endm
@ CREATE HEADER Builds a header for create function
.macro __CREATE fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _docreate
.endm
@ VARIABLE HEADER Builds a header for a variable (user for 2VARIBLE)
.macro __VARIABLE fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _dovar
.endm
@ VOCABULARY HEADER Builds a header for vocabularies
.macro __VOCABULARY fncName,lenx,assmName,type=0
__CORE "\fncName",\lenx,\assmName,\type
.word _dovoc
.endm
@ CONSTANT HEADER Builds a header for constants
.macro __CONSTANT fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _doconstant
.endm
@ USER HEADER Builds a header for user variables
.macro __USER fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _douser
.endm
@ USER-DEFER HEADER Builds a header for user defered words
.macro __USER_DEFER fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _douser_defer
.endm
@ DEFER HEADER Builds a header for defered words
.macro __DEFER fncName,lenx,assmName,type
__CORE "\fncName",\lenx,\assmName,\type
.word _dodefer
.endm
/* vocabulary switching while assembly */
.macro startroot
.set link,rootlink
.endm
.macro exitroot
.set rootlink,link
.endm
.macro startforth
.set link,forthlink
.endm
.macro exitforth
.set forthlink,link
.endm
.macro startfiles
.set link,fileslink
.endm
.macro exitfiles
.set fileslink,link
.endm
.macro starteditor
.set link,editorlink
.endm
.macro exiteditor
.set editorlink,link
.endm
.macro startassembler
.set link,assemblerlink
.endm
.macro exitassmbler
.set assemberlink,link
.endm
/******************memory map****************************/
.equ .bytesperbuffer, 1024
.equ .hashbuffers, 8
.equ .size_bcb, 12 /* bufferControlBlock*/
.equ user_sz, 0x0002000
.equ sp_sz, 0x0000100 @data stack area
.equ rp_sz, 0x0000100 @return stack area
.equ fp_sz, 0x0000080 @frame stack area
.equ bufx_sz, 0x0000010
.equ tib_sz, 0x0000100
.equ tickword_sz, 0x0000100
.equ squote_sz, 0x0000080
.equ ttymem_sz, 0x0000100
.equ keyin_sz, 0x0000010
.equ mem_sz, 0x0010000 @this can be increased
.equ em, .toram + mem_sz/2
.equ .tofirst, em - (.hashbuffers*.bytesperbuffer)
.equ .tobcbs, .tofirst -(.hashbuffers*.size_bcb)
.equ .tobuf, .tobcbs - .hashbuffers
.equ .todisk, .tobuf - 8
.equ .totib, .todisk - tib_sz
.equ .rp0, .totib - bufx_sz
.equ .sp0, .rp0 - rp_sz
.equ fp_mem, .sp0 - sp_sz
.equ user_mem, fp_mem - fp_sz - user_sz
.equ tickword_mem, user_mem - tickword_sz
.equ squote_mem, tickword_mem - squote_sz
.equ tty_mem, squote_mem - ttymem_sz
.equ keyin_mem, tty_mem - keyin_sz
.equ diskbuffer_size, em - .todisk
.equ $word, tickword_mem
.section .data
.align 2
/**********************************************************************/
/* inter interpreter plus defining words execution words
/**********************************************************************/
.section .text
label _unnest
popr ip,rsp
label _next
popr w,ip
popr pc,w
label _pushr1
push {r1}
label _pushr0
push {r0}
popr w,ip
popr pc,w
.macro exit
b _unnest
.endm
.macro next
b _next
.endm
.macro pushr0
b _pushr0
.endm
.macro pushr1
b _pushr1
.endm
label _nest
pushr ip,rsp @ put the present ip on the return stack
mov ip,w
popr w,ip
popr pc,w
label _dodoes
pushr ip,rsp
mov ip,lr
pushr w,sp
next
label _dovar
ldr r0,[w]
pushr0
label _doconstant
popr r0,w
pushr0
label _do2constant
popr r1,w
popr r0,w
pushr1
label _docreate
mov r0,w
pushr0
label _dovoc
mov r0,w
ldr r1,_cntxt
ldr r1,[r1,#4]
str r0,[r1]
next
_cntxt: .word _context
label _dodefer
ldr w,[w]
ldr w,[w]
popr pc,w
label _douser_defer
ldr r0,.up
ldr r0,[r0]
ldr r1,[w]
add r0,r0,r1,lsl #2
ldr w,[r0]
popr pc,w
label _douser
ldr r0,.up
ldr r0,[r0]
ldr r1,[w]
add r0,r0,r1,lsl #2
pushr0
.up: .word $up
/**********************************************************************/
/*** set up vocabulary links ***********/
.set view, 0
.set userNumber, 0
.set link, 0
.set rootlink, 0
.set forthlink, 0
.set fileslink, 0
.set editorlink, 0
.set assemblerlink,0
/**********************************************************************/
/**********************************************************************/
.section .data
label $word @$
.rept 0x0100 @ 256 chars
.byte 0x00
.endr
.set MAXOUT, 127
.set MAXLINE, 48
/* defered vectors */
.align 2
.dotprompt: .word _dotok
.status: .word _noop
.beep: .word _noop
.del_in: .word _bs_in
.receive: .word _key
.cr: .word _pcrp
.source: .word _psourcep
.continued:
.undefined: .word _pundefinedp
.number: .word _dnumber
.where: .word _dot
.error: .word _perrorp
.interactive:
.word _noop
.create: .word _pcreatep
.boot: .word _noop
.default: .word _command
.keypt: .word 0
/* user data section */
.section .data
.align 2
$0link: .word 0
$1sp0: .word .sp0
$2rp0: .word .rp0
$3dp: .word _rompt
$rompt: .word .torom
$rampt: .word .toram
/******Variables**********/
$up: .word $0link
$nout: .word 0
$nline: .word 0
$base: .word 10
$hld: .word 0
$state: .word 0
$toin: .word 0
$csp: .word 0
$runvoc: .word 0
$current: .word 0
$context: .word 0,0,0,0,0,0,0,0,0,0
$voclink: .word linkassembler
$blk: .word 0x856
$dpl: .word 0
$last: .word 0
$toexit: .word 0
$caps: .word 0
$lasttoin: .word 0
$endq: .word 0
$warning: .word -1
$sqbuf: .word 0
$view: .word 0
$hashtib: .word 0
$fileslink: .word 0
$span: .word 0
$ticktib: .word .totib @$
/*
.load: .word _ploadp
.word _pcontinuedp
.create0: .word _pcreate0p
.update: .word _pupdatep
.read_block:
.word _pread_blockp
.write_block:
.word _pwrite_blockp
*/
/*************************************************************************/
/*************************************************************************/
startforth
/*************************************************************************/
.section .text
.align 2
__USER "LINK",4,"_link"
.word 0
__USER "SP0",3,"_sp0"
.word 1
__USER "RP0",3,"_rp0"
.word 2
__USER_DEFER "DP",2,"_dp"
.word 3
__USER "ROMPT",5,"_rompt"
.word 4
__USER "RAMPT",5,"_rampt"
.word 5
.section .text
__VARIABLE "UP",2,_up
.word $up
__VARIABLE "#OUT",4,"_nout"
.word $nout
__VARIABLE "#LINE",5,"_nline"
.word $nline
__VARIABLE "BASE",4,"_base"
.word $base
__VARIABLE "HLD",3,"_hld"
.word $hld
__VARIABLE "STATE",5,"_state"
.word $state
__VARIABLE ">IN",3,"_toin"
.word $toin
__VARIABLE "CSP",3,"_csp"
.word $csp
__VARIABLE "RUN-VOC",7,"_run_voc"
.word $runvoc
__VARIABLE "CURRENT",7,"_current"
.word $current
__VARIABLE "CONTEXT",7,"_context"
.word $context
__VARIABLE "VOC-LINK",8,"_voc_link"
.word $voclink
__VARIABLE "BLK",3,"_blk"
.word $blk
__VARIABLE "DPL",3,"_dpl"
.word $dpl
__VARIABLE "LAST",4,"_last"
.word $last
__VARIABLE ">EXIT",4,"_toexit"
.word $toexit
__VARIABLE "CAPS",4,"_caps"
.word $caps
__VARIABLE "LAST>IN",7,"_lasttoin"
.word $lasttoin
__VARIABLE "END?",4,"_endq"
.word $endq
__VARIABLE "WARNING",7,"_warning"
.word $warning
__VARIABLE "S\"BUF",5,"_squotebuf"
.word $sqbuf
__VARIABLE "VIEW",4,"_view"
.word $view
__VARIABLE "#TIB",4,"_hashtib"
.word $hashtib
__VARIABLE "FILE-LINK",9,"_file_link"
.word $fileslink
__VARIABLE "SPAN",4,"_span"
.word $span
__VARIABLE "'TIB",4,"_ticktib"
.word $ticktib @.totib
/*
__USER "FILE",4,"_file"
.word $FILE
__USER "IN-FILE",7,"_in_file"
.word $INFILE
__USER "'BCB",4,"_tickbcb"
.word $'BCB
*/
/* DEFER */
__DEFER ".PROMPT",7,"_dotprompt"
.word .dotprompt
__DEFER "STATUS",6,"_status"
.word .status
__DEFER "BEEP",4,"_beep"
.word .beep
__DEFER "DEL-IN",6,"_del_in"
.word .del_in
__DEFER "RECEIVE",7,"_receive"
.word .receive
__DEFER "CR",2,"_cr"
.word .cr
__DEFER "SOURCE",6,"_source"
.word .source
@ __DEFER "USERDEFER",9,"_userdefer"
@ .word .userdefer
__DEFER "UNDEFINED",9,"_undefined"
.word .undefined
__DEFER "NUMBER",6,"_number"
.word .number
__DEFER "WHERE",5,"_where"
.word .where
__DEFER "ERROR",5,"_error"
.word .error
__DEFER "INTERACTIVE",11,"_interactive"
.word .interactive
__DEFER "CREATE",6,"_create"
.word .create
__DEFER "BOOT",4,"_boot"
.word .boot
__DEFER "DEFAULT",7,"_default"
.word .default
@ __DEFER "EMIT",4,"_emit",0
/* __DEFER "UPDATE",6,"_update"
.word .update
__DEFER "READ-BLOCK",10,"_read_block"
.word .read_block
__DEFER "WRITE-BLOCK",11,"_write_block"
.word .write_block
__DEFER "LOAD",4,"_load"
.word .load
__DEFER "CONTINUED",9,"_continued"
.word .continued */
/* __DEFER "CREATE0",7,"_create0"
.word .create0 */
/******************************************************************
__CONSTANT "scr-limit",9,"_scr_limit"
.word 512
__CONSTANT "#buffers",8,"_hashbuffers"
.word .hashbuffers
__CONSTANT "b/buf",5,"_bperbuf"
.word .bytesperbuffer
__CONSTANT "size-bcb",8,"_size_bcb"
.word .size_bcb
__CONSTANT "blk/file",8,"_blkperfile"
.word 1000
__CONSTANT "first",5,"_first"
.word .tofirst
__CONSTANT ">bcbs",5,"_tobcbs"
.word .tobcbs
__CONSTANT ">buf",4,"_tobuf"
.word .tobuf
******************************************************************/
__CONSTANT ">TIB",4,"_totib"
.word .totib
__CONSTANT "#VOCS",5,"_hashvocs"
.word 8
__CONSTANT "MAXOUT",6,"_maxout"
.word MAXOUT
/******************************************************************
******************************************************************/
.section .text
/* ROOT */
__VOCABULARY "ROOT",4,"_root"
.word .root
linkroot: .word 0
/* FORTH */
__VOCABULARY "FORTH",5,"_forth"
.word .forth
linkforth: .word linkroot
/* FILES */
__VOCABULARY "FILES",5,"_files"
.word .files
linkfiles: .word linkforth
/* EDITOR */
__VOCABULARY "EDITOR",6,"_editor"
.word .editor
linkeditor: .word linkfiles
/* ASSEMBLER */
__VOCABULARY "ASSEMBLER",9,"_assembler"
.word .assembler
linkassembler:
.word linkeditor
/*&EXECUTE (i*x xt -- j*x) "execute" &*/
__CODE "EXECUTE",7,"_execute"
pop {w}
popr pc,w
/* 16 ( -- 16 ) */
__CODE "16",2,"_16"
mov r0,#16
pushr0
/* (REG) ( n -- n ) DEBUGGING WORDS */
/* __CODE "(REG)",5,"_pregp" */
/**********************************************************
ldr r0,[sp] @ top item on stack
mov r1,#32
bl shownow
/**********************************************************
next
/******REG** ( n -- n ) ****
__COLON "REG",3,"_reg"
.word _pregp
.word _key
.word _drop
.word _exit
/*********************************************************/
/* DUMP ( addr len -- ) */
/*: DUMP BASE @ -ROT HEX .HEAD
BOUNDS DO I DLN KEY? ?LEAVE 16 +LOOP BASE ! ; */
__COLON "DUMP",4,"_dump"
.word _base
.word _fetch
.word _mrot
.word _hex
.word _dothead
.word _bounds
.word _pdop
1: .word _i
.word _dln
.word _keyq
.word _pqleavep
.word 2f
.word _16
.word _pplusloopp
.word 1b
2: .word _unloop
.word _base
.word _store
.word _exit
/*: .HEAD ( addr len -- addr len )
CR 9 SPACES OVER 16 0
DO I 8 = NEAGATE SPACES DUP 15 AND 3 U.R 1+ LOOP
2 SPACES 16 0
DO DUP 15 AND 1 U.R 1+ LOOP DROP ; */
__COLON ".HEAD",5,"_dothead"
.word _cr
.word _plitp
.word 9
.word _spaces
.word _over
.word _16
.word _0
.word _pdop
1: .word _i
.word _8
.word _equ
.word _negate
.word _spaces
.word _dup
.word _15
.word _and
.word _3
.word _udotr
.word _1plus
.word _ploopp
.word 1b
.word _unloop
.word _2
.word _spaces
.word _16
.word _0
.word _pdop
2: .word _dup
.word _15
.word _and
.word _1
.word _udotr
.word _1plus
.word _ploopp
.word 2b
.word _unloop
.word _drop
.word _exit
/*: .LINE ( addr -- ) 16 0
DO I 8 = NEGATE SPACES DUP I + C@ SPACE 2 U.L LOOP ; */
__COLON ".LINE",5,"_dotline"
.word _16
.word _0
.word _pdop
1: .word _i
.word _8
.word _equ
.word _negate
.word _spaces
.word _dup
.word _i
.word _plus
.word _cfetch
.word _space
.word _2
.word _udotl
.word _ploopp
.word 1b
.word _unloop
.word _exit
/*: .CHRS ( addr -- ) 16 0
DO DUP I + C@ EMIT. LOOP ; */
__COLON ".CHRS",5,"_dotchrs"
.word _plitp
.word 16
.word _0
.word _pdop
1: .word _dup
.word _i
.word _plus
.word _cfetch
.word _emitdot
.word _ploopp
.word 1b
.word _unloop
.word _exit
/*: DLN ( addr -- ) CR DUP 8 U.R SPACE
.LINE 2 SPACES .CHARS DROP ; */
__COLON "DLN",3,"_dln"
.word _cr
.word _dup
.word _8
.word _udotr
.word _space
.word _dotline
.word _2
.word _spaces
.word _dotchrs
.word _drop
.word _exit
/* DUMPW ( addr len -- ) DUMP WORDS 32 BITS*/
/*: DUMPW SWAP ALIGNED SWAP BASE @ -ROT HEX .HEADW
BOUNDS DO I DLNW KEY? ?LEAVE 32 +LOOP BASE ! ; */
__COLON "DUMPW",5,"_dumpw"
.word _swap
.word _plum
.word _swap
.word _base
.word _fetch
.word _mrot
.word _hex
.word _dotheadw
.word _bounds
.word _pdop
1: .word _i
.word _dlnw
.word _keyq
.word _pqleavep
.word 2f
.word _plitp
.word 32
.word _pplusloopp
.word 1b
2: .word _unloop
.word _base
.word _store
.word _exit
/*: .HEADW ( addr len -- addr len )
CR 10 SPACES OVER 8 0
DO DUP 15 AND 9 U.R SPACE 4+ LOOP
2 SPACES 32 0
DO DUP 15 AND 1 U.R 1+ LOOP DROP ; */
__COLON ".HEADW",6,"_dotheadw"
.word _cr
.word _plitp
.word 10
.word _spaces
.word _over
.word _plitp
.word 8
.word _0
.word _pdop
1: .word _dup
.word _plitp
.word 15
.word _and
.word _plitp
.word 8
.word _udotr
.word _space
.word _4plus
.word _ploopp
.word 1b
.word _unloop
.word _space
.word _plitp
.word 32
.word _0
.word _pdop
2: .word _dup
.word _15
.word _and
.word _1
.word _udotr
.word _1plus
.word _ploopp
.word 2b
.word _unloop
.word _drop
.word _exit
/*: .LINEW ( addr -- ) 32 0
DO DUP I + @ SPACE 8 U.L 4 +LOOP ; */
__COLON ".LINEW",6,"_dotlinew"
.word _plitp
.word 32
.word _0
.word _pdop
1: .word _dup
.word _i
.word _plus
.word _fetch
.word _space
.word _8
.word _udotl
.word _4
.word _pplusloopp
.word 1b
.word _unloop
.word _exit
/*: .CHRSW ( addr -- ) 32 0
DO DUP I + C@ EMIT. LOOP ; */
__COLON ".CHRSW",6,"_dotchrsw"
.word _plitp
.word 32
.word _0
.word _pdop
1: .word _dup
.word _i
.word _plus
.word _cfetch
.word _emitdot
.word _ploopp
.word 1b
.word _unloop
.word _exit
/*: DLNW ( addr -- ) CR DUP 8 U.R SPACE
.LINEW 2 SPACES .CHRSW DROP ; */
__COLON "DLNW",4,"_dlnw"
.word _cr
.word _dup
.word _8
.word _udotr
.word _space
.word _dotlinew
.word _2
.word _spaces
.word _dotchrsw
.word _drop
.word _exit
/*: EMIT. ( c -- ) 127 AND DUP 127 BL WITHIN
IF DROP [ CHAR . ] LITERAL THEN EMIT ; */
__COLON "EMIT.",5,"_emitdot"
.word _plitp
.word 127
.word _and
.word _dup
.word _plitp
.word 127
.word _bl
.word _within
.word _0branch
.word 1f
.word _drop
.word _plitp
.word 0x02E
1: .word _emit
.word _exit
/*: U.L ( u len -- ) >R 0 <# R> 0 ?DO # LOOP #> TYPE ; */
__COLON "U.L",3,"_udotl"
.word _tor
.word _0
.word _lthash
.word _rfrom
.word _0
.word _pqdop
.word 1f
2: .word _hash
.word _ploopp
.word 2b
1: .word _unloop
.word _hashgt
.word _type
.word _exit
/*: BOUNDS ( addr len -- addr+len addr ) OVER + SWAP ;*/
__COLON "BOUNDS",6,"_bounds"
.word _over
.word _plus
.word _swap
.word _exit
/* ' ( "<spaces>name" -- xt) "tick" */
/* : ' DEFINED 0= ?MISSING ; */
__COLON "'",1,"_tick"
.word _defined
.word _0equ
.word _qmissing
.word _exit
/* : COMPOSE ( -- )
BEGIN
BEGIN
BEGIN ?STACK STATE ON
BEGIN DEFINED DUP 0<
WHILE DROP ,
REPEAT
WHILE EXECUTE
REPEAT DUP C@
WHILE NUMBER DPL @ 0<
IF DROP
ELSE SWAP POSTPONE LITERAL
THEN POSTPONE LITERAL
REPEAT DROP BLK @ ABORT" Unfinished compilation."
CR DEPTH SPACES QUERY
REPEAT ; */
__COLON "COMPOSE",7,"_compose"
1: .word _qstack
.word _state
.word _on
2: .word _defined
.word _dup
.word _0lt
.word _0branch
.word 3f
.word _drop
.word _comma
.word _branch
.word 2b
3: .word _0branch
.word 4f
.word _execute
.word _branch
.word 1b
4: .word _dup
.word _cfetch
.word _0branch
.word 5f
.word _number
.word _dpl
.word _fetch
.word _0lt
.word _0branch
.word 6f
.word _drop
.word _branch
.word 7f
6: .word _swap
.word _literal
7: .word _literal
.word _branch
.word 1b
5: .word _drop
.word _blk
.word _fetch
.word _pabortqp
.byte 23
.ascii "Unfinished compilation."
.align 2
.word _cr
.word _depth
.word _spaces
.word _query
.word _branch
.word 1b
/* : (C: "<spaces>name" -- colon-sys ) "colon" */
/* : : ( -- ) CREATE HIDE !CSP CURRENT @ CONTEXT !
COMPOSE ;USES NEST , */
__COLON ":",1,"_colon"
.word _create
.word _hide
.word _storecsp
.word _current
.word _fetch
.word _context
.word _store
.word _compose