-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathMaxima_suma_de_los_caminos_en_una_matriz.hs
174 lines (152 loc) · 5.33 KB
/
Maxima_suma_de_los_caminos_en_una_matriz.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
-- Maxima_suma_de_los_caminos_en_una_matriz.hs
-- Máxima suma de los caminos en una matriz.
-- José A. Alonso Jiménez <https://jaalonso.github.io>
-- Sevilla, 19-octubre-2023
-- ---------------------------------------------------------------------
-- ---------------------------------------------------------------------
-- Los caminos desde el extremo superior izquierdo (posición (1,1))
-- hasta el extremo inferior derecho (posición (3,4)) en la matriz
-- ( 1 6 11 2 )
-- ( 7 12 3 8 )
-- ( 3 8 4 9 )
-- moviéndose en cada paso una casilla hacia la derecha o hacia abajo,
-- son los siguientes:
-- [1,6,11,2,8,9]
-- [1,6,11,3,8,9]
-- [1,6,12,3,8,9]
-- [1,7,12,3,8,9]
-- [1,6,11,3,4,9]
-- [1,6,12,3,4,9]
-- [1,7,12,3,4,9]
-- [1,6,12,8,4,9]
-- [1,7,12,8,4,9]
-- [1,7, 3,8,4,9]
-- La suma de los caminos son 37, 38, 39, 40, 34, 35, 36, 40, 41 y 32,
-- respectivamente. El camino de máxima suma es el penúltimo (1, 7, 12, 8,
-- 4, 9) que tiene una suma de 41.
--
-- Definir la función
-- maximaSuma :: Matrix Int -> Int
-- tal que (maximaSuma m) es el máximo de las sumas de los caminos en la
-- matriz m desde el extremo superior izquierdo hasta el extremo
-- inferior derecho, moviéndose en cada paso una casilla hacia abajo o
-- hacia la derecha. Por ejemplo,
-- λ> maximaSuma (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]])
-- 41
-- λ> maximaSuma (fromList 800 800 [1..])
-- 766721999
-- ---------------------------------------------------------------------
module Maxima_suma_de_los_caminos_en_una_matriz where
import Data.Matrix (Matrix, (!), fromList, fromLists, matrix, nrows, ncols)
import Test.Hspec (Spec, hspec, it, shouldBe)
import Caminos_en_una_matriz (caminos1, caminos2)
-- 1ª definicion de maximaSuma (con caminos1)
-- ==========================================
maximaSuma1 :: Matrix Int -> Int
maximaSuma1 =
maximum . map sum . caminos1
-- Se usará la función caminos1 del ejercicio
-- "Caminos en una matriz" que se encuentra en
-- https://bit.ly/45bYoYE
-- 2ª definición de maximaSuma (con caminos2)
-- ==========================================
maximaSuma2 :: Matrix Int -> Int
maximaSuma2 =
maximum . map sum . caminos2
-- Se usará la función caminos2 del ejercicio
-- "Caminos en una matriz" que se encuentra en
-- https://bit.ly/45bYoYE
-- 3ª definicion de maximaSuma (por recursión)
-- ===========================================
maximaSuma3 :: Matrix Int -> Int
maximaSuma3 m = maximaSuma3Aux m (nf,nc)
where nf = nrows m
nc = ncols m
-- (maximaSuma3Aux m p) calcula la suma máxima de un camino hasta la
-- posición p. Por ejemplo,
-- λ> maximaSuma3Aux (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) (3,4)
-- 41
-- λ> maximaSuma3Aux (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) (3,3)
-- 32
-- λ> maximaSuma3Aux (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) (2,4)
-- 31
maximaSuma3Aux :: Matrix Int -> (Int,Int) -> Int
maximaSuma3Aux m (1,1) = m ! (1,1)
maximaSuma3Aux m (1,j) = maximaSuma3Aux m (1,j-1) + m ! (1,j)
maximaSuma3Aux m (i,1) = maximaSuma3Aux m (i-1,1) + m ! (i,1)
maximaSuma3Aux m (i,j) =
max (maximaSuma3Aux m (i,j-1)) (maximaSuma3Aux m (i-1,j)) + m ! (i,j)
-- 4ª solución (mediante programación dinámica)
-- ============================================
maximaSuma4 :: Matrix Int -> Int
maximaSuma4 m = q ! (nf,nc)
where nf = nrows m
nc = ncols m
q = matrizMaximaSuma m
-- (matrizMaximaSuma m) es la matriz donde en cada posición p se
-- encuentra el máxima de las sumas de los caminos desde (1,1) a p en la
-- matriz m. Por ejemplo,
-- λ> matrizMaximaSuma (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]])
-- ( 1 7 18 20 )
-- ( 8 20 23 31 )
-- ( 11 28 32 41 )
matrizMaximaSuma :: Matrix Int -> Matrix Int
matrizMaximaSuma m = q
where nf = nrows m
nc = ncols m
q = matrix nf nc f
where f (1,1) = m ! (1,1)
f (1,j) = q ! (1,j-1) + m ! (1,j)
f (i,1) = q ! (i-1,1) + m ! (i,1)
f (i,j) = max (q ! (i,j-1)) (q ! (i-1,j)) + m ! (i,j)
-- Comparación de eficiencia
-- =========================
-- La comparación es
-- λ> maximaSuma1 (fromList 11 11 [1..])
-- 1781
-- (3.88 secs, 1,525,812,680 bytes)
-- λ> maximaSuma2 (fromList 11 11 [1..])
-- 1781
-- (1.08 secs, 546,144,264 bytes)
-- λ> maximaSuma3 (fromList 11 11 [1..])
-- 1781
-- (0.55 secs, 217,712,280 bytes)
-- λ> maximaSuma4 (fromList 11 11 [1..])
-- 1781
-- (0.01 secs, 643,832 bytes)
-- Verificación
-- ============
verifica :: IO ()
verifica = hspec spec
spec :: Spec
spec = do
it "e1" $
maximaSuma1 (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) `shouldBe` 41
it "e2" $
maximaSuma1 (fromList 4 4 [1..]) `shouldBe` 73
it "e3" $
maximaSuma2 (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) `shouldBe` 41
it "e4" $
maximaSuma2 (fromList 4 4 [1..]) `shouldBe` 73
it "e5" $
maximaSuma3 (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) `shouldBe` 41
it "e6" $
maximaSuma3 (fromList 4 4 [1..]) `shouldBe` 73
it "e7" $
maximaSuma4 (fromLists [[1,6,11,2],[7,12,3,8],[3,8,4,9]]) `shouldBe` 41
it "e8" $
maximaSuma4 (fromList 4 4 [1..]) `shouldBe` 73
-- La verificación es
-- λ> verifica
--
-- e1
-- e2
-- e3
-- e4
-- e5
-- e6
-- e7
-- e8
--
-- Finished in 0.0034 seconds
-- 8 examples, 0 failures