build.gradle

/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * Copyright 2018-2021 Andres Almiray.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

project.rootProject.ext.theVersion = file('VERSION').text.trim()

allprojects { p ->
    p.version = p.rootProject.ext.theVersion
}

config {
    info {
        name          = rootProject.name
        description   = 'A collection of opinionated Gradle plugins'
        inceptionYear = '2018'
        tags          = ['project', 'configuration']

        specification {
            enabled = false
        }

        implementation {
            enabled = false
        }
    }

    docs {
        javadoc {
            enabled = false
        }

        groovydoc {
            enabled = true
            replaceJavadoc = true
            options {
                link 'https://docs.gradle.org/6.0/javadoc/', 'org.gradle.'
            }
        }
    }

    coverage {
        jacoco {
            toolVersion = jacocoVersion
        }
    }
}

allprojects {
    repositories {
        gradlePluginPortal()
        flatDir { dir rootProject.file('libraries') }
        mavenLocal()
    }
}

projects.subprojects {
    dir('plugins') {
        config {
            info {
                description = project_description
            }

            plugins {
                plugin {
                    name                = project.name - '-gradle-plugin'
                    id                  = project.pluginId
                    implementationClass = project.pluginImplementationClass
                }
            }

            test {
                testLogging {
                    events 'failed'
                    exceptionFormat 'full'
                }
            }
        }

        dependencies {
            compileOnly gradleApi()

            testImplementation gradleApi()
            testImplementation("org.spockframework:spock-core:$spockVersion") {
                exclude group: 'org.codehaus.groovy'
            }
        }

        tasks.withType(ValidateTaskProperties) { validateTaskProperties ->
            validateTaskProperties.failOnWarning = true
            validateTaskProperties.enableStricterValidation = true
        }
    }
}