asg_node_group enhancements

* Add the ability to add custom AWS tags to node resources
* Make asg_termination policies configurable
* Disable terraform to wait for ASG capacity
* Enable configuring asg metrics collection

examples/cluster/main.tf

@@ -21,6 +21,10 @@ module "cluster" {
       groups   = ["system:masters"]
     }
   ]
+
+  tags = {
+    Project = "terraform-aws-eks"
+  }
 }
 
 module "node_group" {

modules/asg_node_group/main.tf

@@ -20,6 +20,7 @@ locals {
   max_size             = floor(var.max_size / length(local.asg_subnets))
   min_size             = ceil(var.min_size / length(local.asg_subnets))
   root_device_mappings = tolist(data.aws_ami.image.block_device_mappings)[0]
+  tags                 = merge(var.cluster_config.tags, var.tags, { "kubernetes.io/cluster/${var.cluster_config.name}" = "owned" })
 }
 
 data "aws_ssm_parameter" "image_id" {
@@ -84,16 +85,31 @@ resource "aws_launch_template" "config" {
     }
   }
 
+  tag_specifications {
+    resource_type = "instance"
+    tags          = local.tags
+  }
+
+  tag_specifications {
+    resource_type = "volume"
+    tags          = local.tags
+  }
+
+  tags = local.tags
+
   key_name = var.key_name
 }
 
 resource "aws_autoscaling_group" "nodes" {
   for_each = local.asg_subnets
 
-  name                = "${local.name_prefix}-${each.key}"
-  min_size            = local.min_size
-  max_size            = local.max_size
-  vpc_zone_identifier = each.value
+  name                      = "${local.name_prefix}-${each.key}"
+  min_size                  = local.min_size
+  max_size                  = local.max_size
+  vpc_zone_identifier       = each.value
+  termination_policies      = var.termination_policies
+  enabled_metrics           = var.enabled_metrics
+  wait_for_capacity_timeout = 0
 
   mixed_instances_policy {
     launch_template {
@@ -133,7 +149,7 @@ resource "aws_autoscaling_group" "nodes" {
   tag {
     key                 = "kubernetes.io/cluster/${var.cluster_config.name}"
     value               = "owned"
-    propagate_at_launch = true
+    propagate_at_launch = false
   }
 
   tag {
@@ -160,5 +176,14 @@ resource "aws_autoscaling_group" "nodes" {
     }
   }
 
+  dynamic "tag" {
+    for_each = local.tags
+    content {
+      key                 = tag.key
+      value               = tag.value
+      propagate_at_launch = false
+    }
+  }
+
   depends_on = [aws_launch_template.config]
 }

modules/asg_node_group/variables.tf

@@ -5,6 +5,7 @@ variable "cluster_config" {
     private_subnet_ids    = map(string)
     node_security_group   = string
     node_instance_profile = string
+    tags                  = map(string)
   })
 }
 
@@ -91,6 +92,12 @@ variable "taints" {
   description = "taints that will be added to the kubernetes node"
 }
 
+variable "tags" {
+  type        = map(string)
+  default     = {}
+  description = "A map of additional tags to apply to this groups AWS resources"
+}
+
 variable "instance_types" {
   type        = list(string)
   description = <<EOF
@@ -112,3 +119,29 @@ variable "security_groups" {
   default     = []
   description = "Additional security groups for the nodes"
 }
+
+variable "termination_policies" {
+  type        = list(string)
+  default     = ["OldestLaunchTemplate", "OldestInstance"]
+  description = "A list of policies to decide how the instances in the auto scale group should be terminated."
+}
+
+variable "enabled_metrics" {
+  type = list(string)
+  default = [
+    "GroupDesiredCapacity",
+    "GroupInServiceInstances",
+    "GroupInServiceCapacity",
+    "GroupMaxSize",
+    "GroupMinSize",
+    "GroupPendingInstances",
+    "GroupPendingCapacity",
+    "GroupStandbyInstances",
+    "GroupStandbyCapacity",
+    "GroupTerminatingInstances",
+    "GroupTerminatingCapacity",
+    "GroupTotalInstances",
+    "GroupTotalCapacity",
+  ]
+  description = "A list of metrics to collect."
+}

modules/cluster/outputs.tf

@@ -7,6 +7,7 @@ locals {
     private_subnet_ids    = var.vpc_config.private_subnet_ids
     node_security_group   = aws_eks_cluster.control_plane.vpc_config.0.cluster_security_group_id
     node_instance_profile = var.iam_config.node_role
+    tags                  = var.tags
   }
 }
 

modules/cluster/variables.tf

@@ -123,7 +123,7 @@ variable "legacy_security_groups" {
 }
 
 variable "tags" {
-  type        = map
+  type        = map(string)
   default     = {}
-  description = "A map of tags to assign to the cluster and cloudwatch log group resources"
+  description = "A map of tags to assign to cluster AWS resources"
 }