compose-module.gradle

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'kotlin-parcelize'

android {
    compileSdk ProjectConfig.compileSdk

    defaultConfig {
        minSdk ProjectConfig.minSdk
        targetSdk ProjectConfig.targetSdk
        versionCode ProjectConfig.versionCode
        versionName ProjectConfig.versionName

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }
    buildFeatures {
        compose true
    }
    composeOptions {
        kotlinCompilerExtensionVersion Compose.composeVersion
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        coreLibraryDesugaringEnabled true

        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
        freeCompilerArgs += [
                "-opt-in=androidx.compose.material.ExperimentalMaterialApi",
                "-opt-in=androidx.compose.material3.ExperimentalMaterial3Api",
                "-opt-in=com.google.accompanist.pager.ExperimentalPagerApi",
                "-opt-in=androidx.compose.foundation.ExperimentalFoundationApi",
                "-opt-in=com.google.accompanist.permissions.ExperimentalPermissionsApi",
                "-opt-in=androidx.compose.ui.ExperimentalComposeUiApi"
        ]
    }
}

dependencies {
    implementation Compose.compiler
    implementation Compose.ui
    implementation Compose.uiToolingPreview
    implementation Compose.runtime
    implementation Compose.navigation
    implementation Compose.viewModelCompose
    implementation Compose.activityCompose
    implementation Compose.hiltNavigationCompose
    implementation Google.material
    implementation Google.material3
    implementation Google.materialIconsCore
    implementation Google.materialIconsExtended

    kapt DaggerHilt.hiltCompiler
    implementation DaggerHilt.hiltAndroid

    testImplementation Testing.junit
    androidTestImplementation Testing.junitAndroidExt
    androidTestImplementation Testing.composeUiTestJunit4
    debugImplementation Testing.composeUiTooling
    debugImplementation Testing.composeUiTestManifest
}