build.gradle

plugins {
  id 'java'
  id 'checkstyle'
  id 'org.jenkins-ci.jpi' version '0.21.0'
  id 'net.saliman.cobertura' version '2.4.0'
  id 'com.github.kt3k.coveralls' version '2.7.1'
}

group = 'org.jenkins-ci.plugins'
archivesBaseName = 'phabricator-plugin'
version = '1.9.8-SNAPSHOT'
description = 'Integrate Jenkins with Phabricator Differentials and Uberalls'

sourceCompatibility = 1.6
targetCompatibility = 1.6

tasks.withType(JavaCompile) {
  options.encoding = 'UTF-8'
}

jenkinsPlugin {
  coreVersion = '1.609.2'
  displayName = 'Phabricator Differential Plugin'
  url = 'https://wiki.jenkins-ci.org/display/JENKINS/Phabricator+Differential+Plugin'
  gitHubUrl = 'https://github.com/uber/phabricator-jenkins-plugin'
  shortName = 'phabricator-plugin'

  developers {
    developer {
      id 'ai'
      name 'Aiden Scandella'
      email 'sc@ndella.com'
    }
  }

  licenses {
    license {
      name 'MIT License'
      url 'http://opensource.org/licenses/MIT'
    }
  }
}

dependencies {
  compile 'org.apache.httpcomponents:httpcore:4.4.1'
  compile 'org.apache.httpcomponents:httpclient:4.4.1'
  jenkinsPlugins 'org.jenkins-ci.plugins:credentials:1.22@jar'

  optionalJenkinsPlugins 'org.jenkins-ci.plugins:junit:1.6@jar'
  optionalJenkinsPlugins 'org.jenkins-ci.plugins:cobertura:1.9.6@jar'

  testCompile 'junit:junit:4.12'
  testCompile 'org.apache.httpcomponents:httpclient:4.3:tests'
  testCompile 'net.sf.trove4j:trove4j:3.0.3'
  testCompile('org.mockito:mockito-core:1.10.19') {
    exclude module: 'hamcrest-core'
  }

  jenkinsTest 'org.jenkins-ci.main:jenkins-war:1.609.2@war'
  jenkinsTest 'org.jenkins-ci.plugins:matrix-project:1.4@jar'
  jenkinsTest 'org.jenkins-ci.main:jenkins-test-harness:1.609.2@jar'
}

configurations.all {
  resolutionStrategy {
    force 'org.apache.httpcomponents:httpclient:4.3:tests'
  }
}

cobertura.coverageFormats = ['html', 'xml']