build.gradle

plugins {
    id "java"
    id "application"
}

application {
    mainClassName = "wearblackallday.seedcandy.SeedCandy"
    archivesBaseName = "SeedCandy"
    version = "1.5.9"
}

repositories {
    mavenCentral()
    maven { url "https://maven.seedfinding.com" }
    maven { url "https://maven.latticg.com" }
    maven { url "https://jitpack.io" }
}

dependencies {
    implementation("com.seedfinding:mc_biome:1.171.1") {transitive(false)}
    implementation("com.seedfinding:mc_core:1.192.1") {transitive(false)}
    implementation("com.seedfinding:mc_feature:1.171.1") {transitive(false)}
    implementation("com.seedfinding:mc_math:1.171.0") {transitive(false)}
    implementation("com.seedfinding:mc_noise:1.171.1") {transitive(false)}
    implementation("com.seedfinding:mc_reversal:1.171.1") {transitive(false)}
    implementation("com.seedfinding:mc_seed:1.171.1") {transitive(false)}
    implementation("com.seedfinding:latticg:1.06") {transitive(false)}

    implementation "com.github.WearBlackAllDay:JavaUtils:0.0.3"
    implementation "com.formdev:flatlaf:3.0"
    implementation "com.formdev:flatlaf-intellij-themes:3.0"

    testImplementation "org.junit.jupiter:junit-jupiter:5.9.0"
}

task fatJar(type: Jar) {
    manifest {
        attributes(
                "Main-Class": "$mainClassName"
        )
    }
    outputs.upToDateWhen { false }
    exclude("META-INF/LICENSE", "META-INF/versions/**", "module-info.class")
    from {
        configurations.runtimeClasspath.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    with jar
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

artifacts {
    archives fatJar
}