build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.0'
        classpath 'com.novoda:bintray-release:0.3.4'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}
ext {

    ARTIFACT_ID = 'gawrapper'
    VERSION_NAME = '0.0.2'
    VERSION_CODE = 2 //your version

    DESCRIPTION = 'Library that wraps the measurement collection api'

    SITE_URL = 'https://github.com/WaiLynnZaw/analytics_wrapper'
    GIT_URL = 'https://github.com/WaiLynnZaw/analytics_wrapper'
    GROUP_NAME = 'none'
    COMPILE_SDK = 25
    BUILD_TOOLS = '25.0.2'

    MODULE_NAME = 'gawrapper'

    LICENSE = 'Apache-2.0'

    DEVELOPER_ID = 'wailynnzaw'
    DEVELOPER_NAME = 'wailynnzaw'
    DEVELOPER_EMAIL = 'wailynnzaw.lamz@gmail.com'

    IS_UPLOADING = project.getGradle().startParameter.taskNames.any{it.contains('bintrayUpload')}
}

subprojects {

    repositories {
        jcenter()
    }

    group = GROUP_NAME
    version = VERSION_NAME

    if (IS_UPLOADING && project.name in ['compiler','api']) {
        println project.name
        apply plugin: 'maven'

        gradle.taskGraph.whenReady { taskGraph ->
            def pomTask = taskGraph.getAllTasks().find{
                it.path == ":$project.name:generatePomFileForMavenPublication"
            }
            if (pomTask == null) return;

            pomTask.doLast {
//                file("build/publications/maven/pom-default.xml").delete()
                println 'Overriding pom-file to make sure we can sync to maven central!'
                pom {
                    //noinspection GroovyAssignabilityCheck
                    project {
                        name "$project.name"
                        artifactId ARTIFACT_ID
                        packaging project.name == 'compiler' ? 'jar' : 'aar'
                        description DESCRIPTION
                        url SITE_URL
                        version VERSION_NAME

                        scm {
                            url GIT_URL
                            connection GIT_URL
                            developerConnection GIT_URL
                        }

                        licenses {
                            license {
                                name LICENSE
                            }
                        }

                        developers {
                            developer {
                                id DEVELOPER_ID
                                name DEVELOPER_NAME
                                email DEVELOPER_EMAIL
                            }
                        }
                    }
                }.writeTo("build/publications/maven/pom-default.xml")
            }
        }
    }
}