%install.cmd

@ECHO OFF
cd /d %~dp0

IF [%1]==[] (set CHANNEL=stable) ELSE (set CHANNEL=%1)
TITLE Pocketmine-MP Install (%CHANNEL%)

set BASE_DIR=%cd%
set BIN_DIR=%BASE_DIR%\bin
set PHP_DIR=%BIN_DIR%\php
set PMMP_DIR=%BIN_DIR%\pmmp
set PHP=%PHP_DIR%\php
set COMPOSER_PHAR=%BIN_DIR%\composer.phar

IF NOT EXIST %BIN_DIR% ( mkdir %BIN_DIR% )

ECHO|set/p=[1/6] Check php binary...
IF EXIST %PHP_DIR% (
    ECHO Already exists.
) ELSE (
    powershell -Command "Invoke-WebRequest https://git.io/pm-php -OutFile php.zip"
    unzip -qo php.zip -d %PHP_DIR% > nul
    del /f php.zip > nul
    ECHO Successfully installed.
)
ECHO.

ECHO|set/p=[2/6] Check composer file...
IF EXIST %COMPOSER_PHAR% (
    ECHO Already exists.
) ELSE (
    powershell -Command "Invoke-WebRequest https://getcomposer.org/composer-stable.phar -OutFile %COMPOSER_PHAR%"
    ECHO Successfully installed.
)
ECHO.

ECHO [3/6] Update pmmp source git...
IF EXIST %PMMP_DIR% (
    cd %PMMP_DIR%
    git checkout %CHANNEL%
    git pull
    git submodule update --init
) ELSE (
    git clone --recursive https://github.com/pmmp/PocketMine-MP.git %PMMP_DIR% -b %CHANNEL%
)
ECHO.

ECHO [4/6] Update composer dependency...
cd %PMMP_DIR%
%PHP% %COMPOSER_PHAR% install --no-dev --classmap-authoritative --ignore-platform-reqs --no-interaction
ECHO.

ECHO [5/6] Build PocketMine-MP...
cd %PMMP_DIR%
%PHP% %COMPOSER_PHAR% make-server
MOVE PocketMine-MP.phar ..\..\PocketMine-MP.phar > nul
ECHO.

ECHO [6/6] Build DevTools...
cd %BASE_DIR%
set DEVTOOLS_PATH=%PMMP_DIR%\tests\plugins\DevTools
set SCRIPT_PATH=%DEVTOOLS_PATH%\src\DevTools\ConsoleScript.php

IF NOT EXIST plugins/ ( MKDIR plugins )
%PHP% -dphar.readonly=0 %SCRIPT_PATH% --make %DEVTOOLS_PATH% --out plugins\DevTools.phar
ECHO.
ECHO.
ECHO [*/*] All processing are done!
PAUSE > nul