Add notifications for Approval Requests

MSDyn365BC.Ntfy/src/EventTypes/ApprovalRequested.Codeunit.al

@@ -0,0 +1,57 @@
+namespace StefanMaron.Ntfy;
+using Microsoft.Sales.Document;
+using System.Automation;
+
+codeunit 71179884 ApprovalRequestedNTSTM implements INtfyEventNTSTM
+{
+
+    procedure SetSettings(NtfyEvent: Record NtfyEventNTSTM)
+    var
+        FilterPageBuilder: FilterPageBuilder;
+    begin
+        FilterPageBuilder.AddTable('Approval Entry', Database::"Approval Entry");
+        if NtfyEvent.FilterText <> '' then
+            FilterPageBuilder.SetView('Approval Entry', NtfyEvent.FilterText);
+        if FilterPageBuilder.RunModal() then begin
+            if not FilterPageBuilder.GetView('Approval Entry').Contains('WHERE') then
+                NtfyEvent.Validate(FilterText, '')
+            else
+                NtfyEvent.Validate(FilterText, FilterPageBuilder.GetView('Approval Entry'));
+            NtfyEvent.Modify(true);
+        end;
+    end;
+
+    procedure ResetSettings(NtfyEvent: Record NtfyEventNTSTM);
+    begin
+        NtfyEvent.Validate(FilterText, '');
+        NtfyEvent.Modify(true);
+    end;
+
+    procedure FilterNtfyEntriesBeforeBatchSend(var NtfyEvent: Record NtfyEventNTSTM; Params: Dictionary of [Text, Text]);
+    begin
+        NtfyEvent.SetRange(UserName, Params.Get('ApproverID'));
+    end;
+
+    procedure DoCallNtfyEvent(NtfyEvent: Record NtfyEventNTSTM; Params: Dictionary of [Text, Text]) ReturnValue: Boolean
+    begin
+        exit(true);
+    end;
+
+    procedure GetMessage(NtfyEvent: Record NtfyEventNTSTM; Params: Dictionary of [Text, Text]) ReturnValue: Text[2048]
+    begin
+        exit(StrSubstNo('%1 | Pending Approval [Go to Approval List](%2)', Params.Get('RecordID'), GetUrl(ClientType::Web, CompanyName, ObjectType::Page, Page::"Requests to Approve")));
+    end;
+
+    [EventSubscriber(ObjectType::Table, Database::"Approval Entry", OnAfterInsertEvent, '', false, false)]
+    local procedure SentNtfyOnAfterReopenSalesDoc(var Rec: Record "Approval Entry")
+    var
+        NtfyEvent: Record NtfyEventNTSTM;
+        Params: Dictionary of [Text, Text];
+    begin
+        if not (Rec.Status in [Rec.Status::Open, Rec.Status::Created]) then exit;
+
+        Params.Add('ApproverID', Rec."Approver ID");
+        Params.Add('RecordID', Format(Rec."Record ID to Approve"));
+        NtfyEvent.SendNotifications(NtfyEvent.EventType::ApprovalRequested, Params);
+    end;
+}

MSDyn365BC.Ntfy/src/EventTypes/EventType.Enum.al

@@ -25,4 +25,9 @@ enum 71179875 EventTypeNTSTM implements INtfyEventNTSTM
         Caption = 'Report finished processing';
         Implementation = INtfyEventNTSTM = ReportFinishedProcessingNTSTM;
     }
+    value(4; ApprovalRequested)
+    {
+        Caption = 'Approval requested';
+        Implementation = INtfyEventNTSTM = ApprovalRequestedNTSTM;
+    }
 }

MSDyn365BC.Ntfy/src/helperInterfaces/RestWrapper.Codeunit.al

@@ -9,6 +9,7 @@ codeunit 71179880 RestWrapperNTSTM implements IRestWrapperNTSTM
     var
         RestClient: Codeunit "Rest Client";
     begin
+        RestClient.SetDefaultRequestHeader('Markdown', 'yes');
         exit(RestClient.Post(RequestUri, Content));
     end;
 }

al.code-workspace

@@ -16,6 +16,7 @@
       "Ntfy",
       "Ntfys",
       "NTSTM"
-    ]
+    ],
+    "al.rootNamespace": "StefanMaron.Ntfy",
   }
-}
+}