-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathiomanager.pas
1428 lines (1227 loc) · 44.5 KB
/
iomanager.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{
This file is part of the Mufasa Macro Library (MML)
Copyright (c) 2009-2012 by Raymond van Venetië and Merlijn Wajer
MML is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
MML is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with MML. If not, see <http://www.gnu.org/licenses/>.
See the file COPYING, included in this distribution,
for details about the copyright.
Input/Output manager for Mufasa Macro Library
}
{$mode objfpc}{$H+}
unit IOManager;
interface
uses
Classes, SysUtils, mufasatypes, graphics, LCLType, bitmaps, LCLIntf, libloader, dynlibs;
type
{ This is the base class for the target functionality. If it provides a target, it extends this.
| Some methods in heregratuitous provide default functionality as a convinence. Only override as nessessary }
{ TTarget }
TTarget = class(TObject)
public
{ ONLY override some of the following methods if the target provides image functions, defaults
| to raise exceptions. GetColor provides default functionality using ReturData of width 1.
| FreeReturnData provides default of doing nothing. }
procedure GetTargetDimensions(out w, h: integer); virtual;
procedure GetTargetPosition(out left, top: integer); virtual;
function GetColor(x,y : integer) : TColor; virtual;
function ReturnData(xs, ys, width, height: Integer): TRetData; virtual;
procedure FreeReturnData; virtual;
procedure ActivateClient; virtual;
function TargetValid: boolean; virtual;
function MouseSetClientArea(x1, y1, x2, y2: integer): boolean; virtual;
procedure MouseResetClientArea; virtual;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean; virtual;
procedure ImageResetClientArea; virtual;
{ Sucky implementation }
function GetError: String; virtual;
function ReceivedError: Boolean; virtual;
procedure ResetError; virtual;
procedure GetMousePosition(out x,y: integer); virtual;
procedure MoveMouse(x,y: integer); virtual;
procedure ScrollMouse(x,y : integer; Lines : integer); virtual;
procedure HoldMouse(x,y: integer; button: TClickType); virtual;
procedure ReleaseMouse(x,y: integer; button: TClickType); virtual;
function IsMouseButtonHeld( button : TClickType) : boolean ; virtual;
{ ONLY override the following methods if the target provides key functions, defaults to
| raise exceptions }
procedure SendString(str: string; keywait, keymodwait: integer); virtual;
procedure HoldKey(key: integer); virtual;
procedure ReleaseKey(key: integer); virtual;
function IsKeyHeld(key: integer): boolean; virtual;
function GetKeyCode(C : char) : integer; virtual;
end;
{ Implements a target that is a raw pixel array, e.g. stuff from a bitmap or a frozen state.
| Currently this uses the pointer as-is, but it might be needed to make a local copy... }
TRawTarget = class(TTarget)
public
constructor Create(rgb: prgb32; w,h: integer; CopyData : boolean = false);
destructor Destroy; override;
procedure GetTargetDimensions(out w, h: integer); override;
procedure GetTargetPosition(out left, top: integer); override;
function ReturnData(xs, ys, width, height: Integer): TRetData; override;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean; override;
procedure ImageResetClientArea; override;
protected
rgb: prgb32;
freedata : boolean;
w,h: integer;
private
ax1, ay1, ax2, ay2: integer;
caset: boolean;
end;
TBitmapTarget = class(TTarget)
public
constructor Create(bitmap: TMufasaBitmap);
destructor Destroy; override;
procedure GetTargetDimensions(out w, h: integer); override;
function ReturnData(xs, ys, width, height: Integer): TRetData; override;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean; override;
procedure ImageResetClientArea; override;
protected
bitmap: TMufasaBitmap;
private
ax1, ay1, ax2, ay2: integer;
caset: boolean;
end;
{ Implements a target that is a Window in the operating system. This class is abstract, i.e.,
| the actual os-specific Implementation of TWindow is in one of the os units. }
{ TWindow_Abstract }
TWindow_Abstract = class(TTarget)
public
procedure GetTargetDimensions(out w, h: integer); override; abstract;
procedure GetTargetPosition(out left, top: integer); override; abstract;
function ReturnData(xs, ys, width, height: Integer): TRetData; override; abstract;
function TargetValid: boolean; override; abstract;
function GetError: String; override; abstract;
function ReceivedError: Boolean; override; abstract;
procedure ResetError; override; abstract;
function MouseSetClientArea(x1, y1, x2, y2: integer): boolean; override; abstract;
procedure MouseResetClientArea; override; abstract;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean; override; abstract;
procedure ImageResetClientArea; override; abstract;
procedure ActivateClient; override; abstract;
procedure GetMousePosition(out x,y: integer); override; abstract;
procedure MoveMouse(x,y: integer); override; abstract;
procedure ScrollMouse(x,y : integer; Lines : integer); override; abstract;
procedure HoldMouse(x,y: integer; button: TClickType); override; abstract;
procedure ReleaseMouse(x,y: integer; button: TClickType); override; abstract;
function IsMouseButtonHeld( button : TClickType) : boolean;override; abstract;
procedure SendString(str: string; keywait, keymodwait: integer); override; abstract;
procedure HoldKey(key: integer); override; abstract;
procedure ReleaseKey(key: integer); override; abstract;
function IsKeyHeld(key: integer): boolean; override; abstract;
function GetKeyCode(C : char) : integer; override; abstract;
end;
{ Contains the pointers to a non-internal target implementation using the EIOS specification.
| N.B. this *is* the specification that I will finalize the speficication as... Once this is
| finalized that is. Trust me, its >9000 times easier to use a buffer across the language
| barrier. And the internal target implementation of EIOS will make that verry efficient. }
TEIOS_Client = record
RequestTarget: function(initdata: PChar): pointer; stdcall;
ReleaseTarget: procedure(target: pointer); stdcall;
GetTargetDimensions: procedure(target: pointer; var w, h: integer); stdcall;
GetTargetPosition: procedure(var left, top: integer); stdcall;
GetImageBuffer: function(target: pointer): prgb32; stdcall;
UpdateImageBuffer: procedure(target: pointer); stdcall;
UpdateImageBufferBounds: procedure(target: pointer; sx,sy,ex,ey: integer); stdcall;
GetMousePosition: procedure(target: pointer; var x,y: integer); stdcall;
MoveMouse: procedure(target: pointer; x,y: integer); stdcall;
ScrollMouse: procedure(target : pointer; x,y : integer; lines : integer); stdcall;
HoldMouse: procedure(target: pointer; x,y: integer; button: integer); stdcall;
ReleaseMouse: procedure(target: pointer; x,y: integer; button: integer); stdcall;
IsMouseButtonHeld : function (target : pointer; button: integer): boolean; stdcall;
SendString: procedure(target: pointer; str: PChar; keywait, keymodwait: integer); stdcall;
HoldKey: procedure(target: pointer; key: integer); stdcall;
ReleaseKey: procedure(target: pointer; key: integer); stdcall;
IsKeyHeld: function(target: pointer; key: integer): boolean; stdcall;
GetKeyCode : function(target : pointer; C : char) : integer; stdcall;
end;
{ Implements a EIOS target. This is, for all intensive purposes, a TRawTarget with added
| key and mouse methods, as well as the capability to request a buffer update. N.B. that
| some EIOS implementors can and will update the buffer on their own. In that case, the
| UpdateImageBuffer call is just a call to an empty method, OR does not exist. In the case
| of an EIOS client not needing a method defined, it will not be exported and will be set
| to NIL here. I think. Will get back to that. }
{ TEIOS_Target }
TEIOS_Target = class(TTarget)
public
constructor Create(client: TEIOS_Client; initval: String);
destructor Destroy; override;
function MouseSetClientArea(x1, y1, x2, y2: integer): boolean; override;
procedure MouseResetClientArea; override;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean; override;
procedure ImageResetClientArea; override;
procedure GetTargetDimensions(out w, h: integer); override;
procedure GetTargetPosition(out left, top: integer); override;
function ReturnData(xs, ys, width, height: Integer): TRetData; override;
procedure GetMousePosition(out x,y: integer); override;
procedure MoveMouse(x,y: integer); override;
procedure ScrollMouse(x,y : integer; Lines : integer); override;
procedure HoldMouse(x,y: integer; button: TClickType); override;
procedure ReleaseMouse(x,y: integer; button: TClickType); override;
function IsMouseButtonHeld( button : TClickType) : boolean;override;
procedure SendString(str: string; keywait, keymodwait: integer); override;
procedure HoldKey(key: integer); override;
procedure ReleaseKey(key: integer); override;
function IsKeyHeld(key: integer): boolean; override;
function GetKeyCode(C : char) : integer; override;
private
client: TEIOS_Client;
target: pointer;
buffer: prgb32;
width,height: integer;
{ (Forced) Client Area }
mx1, my1, mx2, my2: integer;
ix1, iy1, ix2, iy2: integer;
mcaset, icaset: Boolean;
procedure MouseApplyAreaOffset(var x, y: integer);
procedure ImageApplyAreaOffset(var x, y: integer);
end;
{ This is just a class that loads EIOS clients (like SMART) and sets them up to be used
| as targets. I hope to have a method like...
| function SetTarget(eios_name: pchar; init_args: variant): integer;
| where the init_args variant will be implied to be anything that can be cast to a pointer
| in the binary side after it gets out of PascalScript. So, the only thing to setup SMART
| would be the single call....
| SetTarget('SMART',SmartSetupRecord);
| Sexy, right? ;}
TEIOS_Controller = class(TGenericLoader)
public
constructor Create();
destructor Destroy; override;
function ClientExists(name: string): boolean;
function GetClient(name: string): TEIOS_Client;
protected
function InitPlugin(plugin: TLibHandle): boolean; override;
private
clients: array of TEIOS_Client;
function FindClient(name: string): integer;
end;
{Basically like TEIOS_Client, only this is exported to some plugin, whilst TEIOS_Client is Imported
Not all functions have to be 'set', it depends on the kind of target (Image/KeyMouse) }
TTarget_Exported = record
Target : Pointer;
GetTargetDimensions: procedure(target: pointer; var w, h: integer); stdcall;
GetTargetPosition: procedure(target: pointer; var top, left: integer); stdcall;
GetColor : function(target: pointer;x,y : integer) : integer; stdcall;
ReturnData : function(target: pointer;xs, ys, width, height: Integer): TRetData; stdcall;
FreeReturnData : procedure(target: pointer); stdcall;
GetMousePosition: procedure(target: pointer; var x,y: integer); stdcall;
MoveMouse: procedure(target: pointer; x,y: integer); stdcall;
ScrollMouse: procedure(target: pointer; x,y : integer; Lines : integer); stdcall;
HoldMouse: procedure(target: pointer; x,y: integer; left: boolean); stdcall;
ReleaseMouse: procedure(target: pointer; x,y: integer; left: boolean); stdcall;
IsMouseButtonHeld : function (target : pointer; left : boolean) : boolean;stdcall;
SendString: procedure(target: pointer; str: PChar; keywait, keymodwait: integer); stdcall;
HoldKey: procedure(target: pointer; key: integer); stdcall;
ReleaseKey: procedure(target: pointer; key: integer); stdcall;
IsKeyHeld: function(target: pointer; key: integer): boolean; stdcall;
GetKeyCode : function(target : pointer; C : char) : integer; stdcall;
end;
{ This class specifies the object that will go in the ThreadVar to give the script access
| to targets. This class is abstract, i.e., the actual os-specific Implementation of
| TIOManager is in one of the os units.
| I assume you Simba people know what the methods you made do, and I'm mantaining
| Name -> Function compatibility from the TWindow and TMInput classes (e.g. key, image,
| and window functions). I decided to split targeting into input/output == image/keymouse,
| since they sometimes are treated as seperate entities. }
{ TIOManager_Abstract }
TIOManager_Abstract = class(TObject)
public
constructor Create;
constructor Create(plugin_dir: string);
destructor Destroy; override;
{ Sucky implementation }
function GetError: String;
function ReceivedError: Boolean;
procedure ResetError;
procedure SetDesktop; virtual; abstract;
function SetTarget(ArrPtr: PRGB32; Size: TPoint): integer; overload;
function SetTarget(bmp : TMufasaBitmap) : integer; overload;
function SetTarget(name, initargs: string): integer; overload;
function TargetValid: Boolean;
procedure BitmapDestroyed(Bitmap : TMufasaBitmap);
function GetColor(x,y : integer) : TColor;
function ReturnData(xs, ys, width, height: Integer): TRetData;
procedure FreeReturnData;
procedure GetDimensions(out W, H: Integer);
procedure GetPosition(var Left, Top: Integer);
procedure ActivateClient;
function IsFrozen: boolean;
procedure SetFrozen(makefrozen: boolean);
function MouseSetClientArea(x1, y1, x2, y2: integer): boolean;
procedure MouseResetClientArea;
function ImageSetClientArea(x1, y1, x2, y2: integer): boolean;
procedure ImageResetClientArea;
procedure GetMousePos(var X, Y: Integer);
procedure MoveMouse(X, Y: Integer);
procedure ScrollMouse(x,y : integer; Lines : integer);
procedure HoldMouse(x,y : integer; button: TClickType);
procedure ReleaseMouse(x,y : integer; button: TClickType);
procedure ClickMouse(X, Y: Integer; button: TClickType);
function IsMouseButtonDown( button : TClickType) : boolean;
procedure KeyUp(key: Word);
procedure KeyDown(key: Word);
procedure PressKey(key: Word);
procedure SendText(text: string; keywait, keymodwait: integer);
function isKeyDown(key: Word): Boolean;
function GetKeyCode(c : char) : integer;
function GetImageTarget: TTarget; overload;
function GetKeyMouseTarget: TTarget; overload;
function ExportImageTarget : TTarget_Exported; overload;
function ExportKeyMouseTarget : TTarget_Exported; overload;
procedure GetImageTarget(var idx: integer); overload;
procedure GetKeyMouseTarget(var idx: integer); overload;
procedure SetImageTarget(idx: integer);
procedure SetKeyMouseTarget(idx: integer);
procedure FreeTarget(idx: integer);
procedure SetState(val: Boolean);
function GetProcesses: TSysProcArr; virtual; abstract;
procedure SetTargetEx(Proc: TSysProc); virtual; abstract;
protected
function SetImageTarget(target: TTarget): integer;
function SetKeyMouseTarget(target: TTarget): integer;
function SetBothTargets(target: TTarget): integer;
procedure NativeInit; virtual; abstract;
procedure NativeFree; virtual; abstract;
private
keymouse: TTarget;
image: TTarget;
frozen: TTarget;
freezebuffer: prgb32;
bothsame: boolean;
FStopping: Boolean;
idxarr: array of TTarget;
function GetTargetIdx(target: TTarget): integer;
function GetIdxTarget(idx: integer): TTarget;
property Stopping: Boolean Read FStopping write SetState;
end;
{These wrappers are for an exported TTarget_Exported. This is done so a plugin can acces the current target and use its methodes}
procedure TTarget_Exported_GetTargetDimensions(target: pointer; var w, h: integer); stdcall;
procedure TTarget_Exported_GetTargetPosition(target: pointer; var left, top: integer); stdcall;
function TTarget_Exported_GetColor (target: pointer;x,y : integer) : integer; stdcall;
function TTarget_Exported_ReturnData (target: pointer;xs, ys, width, height: Integer): TRetData; stdcall;
procedure TTarget_Exported_FreeReturnData(target: pointer); stdcall;
procedure TTarget_Exported_GetMousePosition(target: pointer; var x,y: integer); stdcall;
procedure TTarget_Exported_MoveMouse(target: pointer; x,y: integer); stdcall;
procedure TTarget_Exported_ScrollMouse(target: pointer; x,y : integer; Lines : integer); stdcall;
procedure TTarget_Exported_HoldMouse(target: pointer; x,y: integer; left: boolean); stdcall;
procedure TTarget_Exported_ReleaseMouse(target: pointer; x,y: integer; left: boolean); stdcall;
function TTarget_Exported_IsMouseButtonHeld(target: pointer; left : boolean) : boolean;stdcall;
procedure TTarget_Exported_SendString(target: pointer; str: PChar; keywait, keymodwait: integer); stdcall;
procedure TTarget_Exported_HoldKey(target: pointer; key: integer); stdcall;
procedure TTarget_Exported_ReleaseKey(target: pointer; key: integer); stdcall;
function TTarget_Exported_IsKeyHeld(target: pointer; key: integer): boolean; stdcall;
function TTarget_Exported_GetKeyCode(target : pointer; C : char) : integer; stdcall;
implementation
uses FileUtil,
{$IFDEF MSWINDOWS} os_windows {$ENDIF}
{$IFDEF LINUX} os_linux {$ENDIF};
var eios_controller: TEIOS_Controller;
//***implementation*** TIOManager
constructor TIOManager_Abstract.Create(plugin_dir: string);
begin
inherited Create;
SetLength(idxarr,0);
eios_controller.AddPath(plugin_dir);
keymouse:= nil;
image:= nil;
frozen:= nil;
FStopping:=False;
NativeInit;
SetDesktop;
end;
constructor TIOManager_Abstract.Create;
begin
inherited Create;
keymouse:= nil;
image:= nil;
frozen:= nil;
NativeInit;
SetDesktop;
end;
destructor TIOManager_Abstract.Destroy;
var
i: integer;
begin
for i:= high(idxarr) downto 0 do
idxarr[i].Free;
end;
procedure TIOManager_Abstract.FreeTarget(idx: integer);
begin
if idx > high(idxarr) then
raise Exception.Create('Invalid target index');
if idxarr[idx] = nil then
raise Exception.Create('Double free of target');
idxarr[idx].Free;
idxarr[idx]:= nil;
end;
function TIOManager_Abstract.GetTargetIdx(target: TTarget): integer;
var
i: integer;
begin
result:= -1;
for i:= 0 to high(idxarr) do
begin
if idxarr[i] = target then
begin
result:= i;
exit;
end;
if (idxarr[i] = nil) and (result = -1) then
result:= i;
end;
if result = -1 then
begin
SetLength(idxarr,Length(idxarr) + 1);
result:= high(idxarr);
end;
idxarr[result]:= target;
end;
function TIOManager_Abstract.GetIdxTarget(idx: integer): TTarget;
begin
if idx > high(idxarr) then
raise Exception.Create('Invalid target index');
if idxarr[idx] = nil then
raise Exception.Create('No target with specified index');
result:= idxarr[idx];
end;
function TIOManager_Abstract.SetImageTarget(target: TTarget): integer;
begin
if IsFrozen then
raise Exception.Create('You cannot set a target when Frozen');
result:= GetTargetIdx(target);
image:= target;
end;
function TIOManager_Abstract.GetImageTarget: TTarget;
begin
result := image;
end;
function TIOManager_Abstract.SetKeyMouseTarget(target: TTarget): integer;
begin
result:= GetTargetIdx(target);
keymouse:= target;
end;
function TIOManager_Abstract.GetKeyMouseTarget: TTarget;
begin
result := keymouse;
end;
function TIOManager_Abstract.ExportImageTarget: TTarget_Exported;
begin
FillChar(result,sizeof(TTarget_Exported),0);
with result do
begin
Target:= image;
GetTargetDimensions:= @TTarget_Exported_GetTargetDimensions;
GetTargetPosition := @TTarget_Exported_GetTargetPosition;
GetColor:= @TTarget_Exported_GetColor;
ReturnData := @TTarget_Exported_ReturnData;
FreeReturnData:= @TTarget_Exported_FreeReturnData;
end;
end;
function TIOManager_Abstract.ExportKeyMouseTarget: TTarget_Exported;
begin
FillChar(result,sizeof(TTarget_Exported),0);
with result do
begin
Target:= KeyMouse;
GetMousePosition := @TTarget_Exported_GetMousePosition;
MoveMouse := @TTarget_Exported_MoveMouse;
ScrollMouse:= @TTarget_Exported_ScrollMouse;
HoldMouse := @TTarget_Exported_HoldMouse;
ReleaseMouse := @TTarget_Exported_ReleaseMouse;
SendString := @TTarget_Exported_SendString;
HoldKey := @TTarget_Exported_HoldKey;
ReleaseKey := @TTarget_Exported_ReleaseKey;
IsKeyHeld := @TTarget_Exported_IsKeyHeld;
GetKeyCode := @TTarget_Exported_GetKeyCode;
end;
end;
function TIOManager_Abstract.SetBothTargets(target: TTarget): integer;
begin
if IsFrozen then
raise Exception.Create('You cannot set a target when Frozen');
result:= GetTargetIdx(target);
image:= target;
keymouse:= target;
end;
procedure TIOManager_Abstract.SetFrozen(makefrozen: boolean);
var
w,h: integer;
buffer: TRetData;
begin
if (makefrozen) and (IsFrozen) then
raise Exception.Create('The window is already frozen.');
if makefrozen then //No need for the Frozen = nil check, already done above with the exception.
begin
frozen:= image;
frozen.GetTargetDimensions(w,h);
buffer:= frozen.ReturnData(0,0,w,h);
image:= TRawTarget.Create(buffer.Ptr,w,h,true);
frozen.FreeReturnData;
end else
begin
if not IsFrozen() then
raise Exception.Create('Unfreeze called when the window is not frozen.')
else
begin
image.Free();
image:= frozen;
frozen:= nil;
end;
end;
end;
function TIOManager_Abstract.IsFrozen: boolean;
begin
result:= frozen <> nil;
end;
function TIOManager_Abstract.GetColor(x,y : integer) : TColor;
begin
result:= image.GetColor(x,y);
end;
function TIOManager_Abstract.ReturnData(xs,ys,width,height: integer): TRetData;
begin
result:= image.ReturnData(xs,ys,width,height);
end;
procedure TIOManager_Abstract.FreeReturnData;
begin
image.freeReturnData();
end;
function TIOManager_Abstract.SetTarget(ArrPtr: PRGB32; Size: TPoint): integer;
begin
result:= SetImageTarget(TRawTarget.Create(ArrPtr,Size.X,Size.Y));
end;
//Only checks the current image target, not targets that might be in the indexes...
procedure TIOManager_Abstract.BitmapDestroyed(Bitmap : TMufasaBitmap);
begin
if image is TBitmapTarget then
if (TBitmapTarget(image).bitmap = Bitmap) and (not FStopping) then
raise Exception.Create('Target bitmap was destroyed!');
end;
function TIOManager_Abstract.SetTarget(bmp : TMufasaBitmap) : integer;
begin
result:= SetImageTarget(TBitmapTarget.Create(bmp));
bmp.OnDestroy:= @BitmapDestroyed;
end;
function TIOManager_Abstract.SetTarget(name, initargs: String): integer;
var
client: TEIOS_Client;
begin
if not eios_controller.ClientExists(name) then
raise Exception.Create('EIOS Client by specified name does not exist');
client:= eios_controller.GetClient(name);
result:= SetBothTargets(TEIOS_Target.Create(client, initargs));
end;
procedure TIOManager_Abstract.SetImageTarget(idx: integer);
begin
image:= GetIdxTarget(idx);
end;
procedure TIOManager_Abstract.SetKeyMouseTarget(idx: integer);
begin
keymouse:= GetIdxTarget(idx);
end;
procedure TIOManager_Abstract.GetImageTarget(var idx: integer);
begin
if IsFrozen then
raise Exception.Create('Cannot get image target while frozen');
idx:= GetTargetIdx(image);
end;
procedure TIOManager_Abstract.GetKeyMouseTarget(var idx: integer);
begin
idx:= GetTargetIdx(keymouse);
end;
function TIOManager_Abstract.TargetValid: Boolean;
begin
result:= false;
if (keymouse <> nil) and (image <> nil) then
result := (keymouse.TargetValid and image.TargetValid);
end;
procedure TIOManager_Abstract.GetDimensions(out W, H: Integer);
begin
image.GetTargetDimensions(w,h)
end;
procedure TIOManager_Abstract.GetPosition(var Left, Top: Integer);
begin
image.GetTargetPosition(Left, Top);
end;
procedure TIOManager_Abstract.ActivateClient;
begin
keymouse.ActivateClient();
{not sure if image needs activation or not, if its a native window keymouse == image so it should be good.}
end;
function TIOManager_Abstract.MouseSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
Result := keymouse.MouseSetClientArea(x1, y1, x2, y2);
end;
procedure TIOManager_Abstract.MouseResetClientArea;
begin
keymouse.MouseResetClientArea;
end;
function TIOManager_Abstract.ImageSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
Result := image.ImageSetClientArea(x1, y1, x2, y2);
end;
procedure TIOManager_Abstract.ImageResetClientArea;
begin
image.ImageResetClientArea;
end;
procedure TIOManager_Abstract.GetMousePos(var X, Y: Integer);
begin
keymouse.GetMousePosition(x,y)
end;
procedure TIOManager_Abstract.MoveMouse(X, Y: Integer);
begin
keymouse.MoveMouse(x,y);
end;
procedure TIOManager_Abstract.ScrollMouse(x, y: integer; Lines: integer);
begin
keymouse.ScrollMouse(x,y,lines);
end;
procedure TIOManager_Abstract.HoldMouse(x,y : integer; button: TClickType);
begin
keymouse.HoldMouse(x,y,button);
end;
procedure TIOManager_Abstract.ReleaseMouse(x,y : integer; button: TClickType);
begin
keymouse.ReleaseMouse(x,y,button);
end;
procedure TIOManager_Abstract.ClickMouse(X, Y: Integer; button: TClickType);
begin
HoldMouse(x,y,button);
//BenLand100 note: probably should wait here
ReleaseMouse(x,y,button);
end;
function TIOManager_Abstract.IsMouseButtonDown(button: TClickType): boolean;
begin
result := keymouse.IsMouseButtonHeld(button);
end;
procedure TIOManager_Abstract.KeyUp(key: Word);
begin
keymouse.ReleaseKey(key)
end;
procedure TIOManager_Abstract.KeyDown(key: Word);
begin
keymouse.HoldKey(key)
end;
procedure TIOManager_Abstract.PressKey(key: Word);
begin
keyup(key);
keydown(key);
end;
procedure TIOManager_Abstract.SendText(text: string; keywait, keymodwait: integer);
begin
keymouse.SendString(text, keywait, keymodwait);
end;
function TIOManager_Abstract.isKeyDown(key: Word): Boolean;
begin
result:= keymouse.IsKeyHeld(key);
end;
function TIOManager_Abstract.GetKeyCode(c: char): integer;
begin
result := keymouse.GetKeyCode(c);
end;
function TIOManager_Abstract.GetError: String;
begin
if keymouse.ReceivedError then
exit(keymouse.GetError);
if image.ReceivedError then
exit(image.GetError);
raise Exception.Create('TIOManager_Abstract.GetError: NO ERROR!');
exit('');
end;
function TIOManager_Abstract.ReceivedError: Boolean;
begin
exit(keymouse.ReceivedError or image.ReceivedError);
end;
procedure TIOManager_Abstract.ResetError;
begin
keymouse.ResetError;
image.ResetError;
end;
// TRUE when STOPPING.
procedure TIOManager_Abstract.SetState(val: Boolean);
begin
FStopping := val;
end;
//***implementation*** TTarget
procedure TTarget.GetTargetDimensions(out w, h: integer);
begin
raise Exception.Create('GetTargetDimensions not available for this target');
end;
procedure TTarget.GetTargetPosition(out left, top: integer);
begin
raise Exception.Create('GetTargetDimensions not available for this target');
end;
function TTarget.GetColor(x,y : integer) : TColor;
begin
with ReturnData(x,y,1,1) do
Result := RGBToColor(Ptr[0].r,Ptr[0].g,Ptr[0].b);
FreeReturnData;
end;
function TTarget.ReturnData(xs, ys, width, height: Integer): TRetData;
begin
raise Exception.Create('ReturnData not available for this target');
end;
procedure TTarget.FreeReturnData;
begin
{do nothing by default}
end;
procedure TTarget.ActivateClient;
begin
raise Exception.Create('ActivateClient not available for this target');
end;
function TTarget.TargetValid: boolean;
begin
result:= true;
end;
function TTarget.MouseSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
raise Exception.Create('MouseSetClientArea not available for this target');
end;
procedure TTarget.MouseResetClientArea;
begin
raise Exception.Create('MouseResetClientArea not available for this target');
end;
function TTarget.ImageSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
raise Exception.Create('ImageSetClientArea not available for this target');
end;
procedure TTarget.ImageResetClientArea;
begin
raise Exception.Create('ImageResetClientArea not available for this target');
end;
function TTarget.GetError: String;
begin
raise Exception.Create('GetError not available for this target');
end;
function TTarget.ReceivedError: Boolean;
begin
raise Exception.Create('ReceivedError not available for this target');
end;
procedure TTarget.ResetError;
begin
raise Exception.Create('ResetError not available for this target');
end;
procedure TTarget.GetMousePosition(out x,y: integer);
begin
raise Exception.Create('GetMousePosition not available for this target');
end;
procedure TTarget.MoveMouse(x,y: integer);
begin
raise Exception.Create('MoveMouse not available for this target');
end;
procedure TTarget.ScrollMouse(x,y : integer; lines : integer);
begin
raise Exception.Create('ScrollMouse is not available for this target');
end;
procedure TTarget.HoldMouse(x,y: integer; button: TClickType);
begin
raise Exception.Create('HoldMouse not available for this target');
end;
procedure TTarget.ReleaseMouse(x,y: integer; button: TClickType);
begin
raise Exception.Create('ReleaseMouse not available for this target');
end;
function TTarget.IsMouseButtonHeld(button: TClickType): boolean;
begin
raise Exception.Create('IsMouseButtonHeld not available for this target');
end;
procedure TTarget.SendString(str: string; keywait, keymodwait: integer);
begin
raise Exception.Create('SendString not available for this target');
end;
procedure TTarget.HoldKey(key: integer);
begin
raise Exception.Create('HoldKey not available for this target');
end;
procedure TTarget.ReleaseKey(key: integer);
begin
raise Exception.Create('ReleaseKey not available for this target');
end;
function TTarget.IsKeyHeld(key: integer): boolean;
begin
raise Exception.Create('IsKeyHeld not available for this target');
end;
function TTarget.GetKeyCode(C: char): integer;
begin
Exception.CreateFMT('GetKeyCode - char (%s) to key is not available for this target.',[c]);
end;
//***implementation*** TEIOS_Target
constructor TEIOS_Target.Create(client: TEIOS_Client; initval: String); begin
inherited Create;
self.client:= client;
self.target:= nil;
if Pointer(client.RequestTarget) <> nil then
self.target:= client.RequestTarget(PChar(initval));
if (self.target = nil) then
raise Exception.Create('Setting EIOS target failed.');
if Pointer(client.GetImageBuffer) <> nil then
self.buffer:= client.GetImageBuffer(target)
else
self.buffer:= nil;
GetTargetDimensions(self.width,self.height);
self.mx1 := 0; self.my1 := 0; self.mx2 := 0; self.my2 := 0;
self.mcaset := false;
self.ix1 := 0; self.iy1 := 0; self.ix2 := 0; self.iy2 := 0;
self.icaset := false;
end;
destructor TEIOS_Target.Destroy; begin
if (client.ReleaseTarget <> nil) and (self.target <> nil) then
client.ReleaseTarget(self.target);
inherited Destroy;
end;
function TEIOS_Target.MouseSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
if ((x2 - x1) > self.width) or ((y2 - y1) > self.height) then
exit(False);
if (x1 < 0) or (y1 < 0) then
exit(False);
mx1 := x1; my1 := y1; mx2 := x2; my2 := y2;
mcaset := True;
end;
procedure TEIOS_Target.MouseResetClientArea;
begin
mx1 := 0; my1 := 0; mx2 := 0; my2 := 0;
mcaset := False;
end;
function TEIOS_Target.ImageSetClientArea(x1, y1, x2, y2: integer): boolean;
begin
if ((x2 - x1) > self.width) or ((y2 - y1) > self.height) then
exit(False);
if (x1 < 0) or (y1 < 0) then
exit(False);
ix1 := x1; iy1 := y1; ix2 := x2; iy2 := y2;
icaset := True;
end;
procedure TEIOS_Target.ImageResetClientArea;
begin
ix1 := 0; iy1 := 0; ix2 := 0; iy2 := 0;
icaset := False;
end;
procedure TEIOS_Target.MouseApplyAreaOffset(var x, y: integer);
begin
if mcaset then
begin
x := x + mx1;
y := y + my1;
end;
end;
procedure TEIOS_Target.ImageApplyAreaOffset(var x, y: integer);
begin
if icaset then
begin
x := x + ix1;
y := y + iy1;
end;
end;
procedure TEIOS_Target.GetTargetDimensions(out w, h: integer);
begin
if Pointer(client.GetTargetDimensions) <> nil then
begin
if icaset then
begin
w := ix2 - ix1;
h := iy2 - iy1;
exit;
end;
client.GetTargetDimensions(target,w,h)
end else
inherited GetTargetDimensions(w,h);
end;
procedure TEIOS_Target.GetTargetPosition(out left, top: integer);
begin
if Pointer(client.GetTargetDimensions) <> nil then
client.GetTargetDimensions(target,left,top)
else
inherited GetTargetDimensions(left,top);
end;
function TEIOS_Target.ReturnData(xs, ys, width, height: Integer): TRetData;
begin
ImageApplyAreaOffset(xs, ys);
if Pointer(client.UpdateImageBufferBounds) <> nil then
client.UpdateImageBufferBounds(target,xs,ys,xs+width,ys+height)
else if Pointer(client.UpdateImageBuffer) <> nil then
client.UpdateImageBuffer(target)
else begin