build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {

    ext {
        compileSdkVersion = 33
        minSdkVersion = 27
        targetSdkVersion = 32

        // Plugins
        hiltPluginVersion = '2.43.2'

        // AndroidX
        paging3Version = '3.1.1'

        // AndroidX UI
        appCompatVersion = '1.6.1'
        constraintLayoutVersion = '2.1.4'
        recyclerViewVersion = '1.2.1'
        materialVersion = '1.8.0'

        // Ktx
        coreKtxVersion = '1.9.0'
        fragmentKtxVersion = '1.5.5'
        lifecycleKtxVersion = '2.5.1'
        viewModelKtxVersion = '2.5.1'

        // External UI
        glideVersion = '4.13.0'

        // Kotlin
        coroutinesVersion = "1.6.1"

        // DI
        hiltVersion = '2.43.2'

        // Networking
        okHttpLoggingVersion = '4.9.1'
        retrofitVersion = '2.9.0'
        gsonVersion = '2.8.9'

        // Testing
        jUnitVersion = '4.13.2'
        extjUnitVersion = '1.1.5'
        mockWebServerVersion = '4.9.1'
    }

    dependencies {
        classpath "com.google.dagger:hilt-android-gradle-plugin:$hiltPluginVersion"
    }
}

plugins {
    id 'com.android.application' version '7.4.1' apply false
    id 'com.android.library' version '7.4.1' apply false
    id 'org.jetbrains.kotlin.android' version '1.8.0' apply false
}

// Applying configuration below to all Android modules
subprojects {
    afterEvaluate { project ->
        if (!project.hasProperty('android')) {
            return
        }

        android {
            compileSdkVersion rootProject.compileSdkVersion

            defaultConfig {
                minSdkVersion rootProject.minSdkVersion
                targetSdkVersion rootProject.targetSdkVersion

                testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
            }

            buildTypes {
                debug {
                    debuggable true
                    minifyEnabled false
                }
                release {
                    minifyEnabled true
                    consumerProguardFiles 'consumer-rules.pro'
                    proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
                }
            }
        }
    }

}