ufbt: init at 0.2.5, flipperzero-toolchain: init at 39

maintainers/maintainer-list.nix

@@ -4532,6 +4532,11 @@
     email = "jupiter@m.rdis.dev";
     name = "Scott Little";
   };
+  CodeRadu = {
+    github = "CodeRadu";
+    githubId = 47945947;
+    name = "Radu";
+  };
   codgician = {
     email = "codgician@outlook.com";
     github = "codgician";

pkgs/by-name/fl/flipperzero-toolchain/package.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  libgcc,
+  libnsl,
+  libxcrypt,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "flipperzero-toolchain";
+  version = "39";
+
+  src = fetchurl {
+    url = "https://update.flipperzero.one/builds/toolchain/gcc-arm-none-eabi-12.3-x86_64-linux-flipper-${version}.tar.gz";
+    hash = "sha256-wETFkjP2b278+FSv/i1eCdutBNaHCdUTvHYLHZiJWFM=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+
+  buildInputs = [
+    libgcc
+    stdenv.cc.cc.lib # for libstdc++.so.6
+    libnsl
+    libxcrypt
+  ];
+
+  sourceRoot = ".";
+
+  shellHook = ''
+    export FBT_TOOLCHAIN_PATH=$out/opt/flipperzero-toolchain
+  '';
+
+  installPhase = ''
+    mkdir -p $out/opt/flipperzero-toolchain/toolchain/x86_64-linux
+    cp -r gcc-arm-none-eabi-12.3-x86_64-linux-flipper/* $out/opt/flipperzero-toolchain/toolchain/x86_64-linux
+    ln -sf ${libnsl}/lib/libnsl.so.3 $out/opt/flipperzero-toolchain/toolchain/x86_64-linux/lib/libnsl.so.2
+    ln -sf ${libxcrypt}/lib/libcrypt.so.2 $out/opt/flipperzero-toolchain/toolchain/x86_64-linux/lib/libcrypt.so.1
+    ln -sf $out/opt/flipperzero-toolchain/toolchain/x86_64-linux $out/opt/flipperzero-toolchain/toolchain/current
+  '';
+
+  meta = {
+    description = "Toolchain for the flipperzero";
+    homepage = "https://github.com/flipperdevices/flipperzero-toolchain";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ CodeRadu ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/uf/ufbt/package.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  setuptools,
+  setuptools-git-versioning,
+  flipperzero-toolchain,
+}:
+
+buildPythonPackage rec {
+  pname = "ufbt";
+  version = "0.2.5";
+  format = "pyproject";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-pQI8pSn5X6ISJ2rlEIfe6je4g7PY8HhKITl1GemMvf8=";
+  };
+
+  propagatedBuildInputs = [
+    setuptools
+    setuptools-git-versioning
+  ];
+
+  makeWrapperArgs = [
+    "--set-default FBT_TOOLCHAIN_PATH ${flipperzero-toolchain}/opt/flipperzero-toolchain"
+  ];
+
+  meta = {
+    description = "Cross-platform tool for building applications for Flipper Zero";
+    mainProgram = "ufbt";
+    homepage = "https://github.com/flipperdevices/flipperzero-ufbt";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ CodeRadu ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -7469,6 +7469,10 @@ with pkgs;
     };
   }));
 
+  ufbt = callPackage ../by-name/uf/ufbt/package.nix {
+    inherit (python3Packages) buildPythonPackage setuptools setuptools-git-versioning;
+  };
+
   ansible-builder = with python3Packages; toPythonApplication ansible-builder;
 
   ansible-doctor = callPackage ../tools/admin/ansible/doctor.nix { };