room31.asc

// Schulgang erster Stock (1) (Ronville Schule)

/****************************
*   Raum-Funktionen
****************************/
function room_Load()
{
  aMusic14.Play();
	//oTuer03.init_object(6);
	Door[eDoorNumKlassenzimmer3].Init(oTuer03, hTuer03);
}


/****************************
*   Tür-Hotspot-Funktionen
****************************/
int Tuer(int x, int y, CharacterDirection dir)
{
	if (any_click_move(x, y, dir))
	{
		if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Das ist ein Klassenzimmer.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Das geht nicht.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Ich habe zur Zeit keinen Unterricht.");
		}
		else if (UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("Lieber nicht.");
			player.Say("Da drin ist gerade Unterricht.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Die ist doch schon zu.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Nette Idee.");
		}
		else if (UsedAction(eActUseInventory))
		{
			if ( player.ActiveInventory == iSchluesselKlasse || player.ActiveInventory == iSchluesselTrophy )
			{
			  player.Say("Dieser Schlüssel passt nicht.");
			}
			else
			{
			  player.Say("Sieht das etwa wie ein Schlüssel aus?");
			}
		}
		else Unhandled();
	}
}

function hTuer01_AnyClick()
{
	return Tuer(130, 100, eDirectionLeft);
}

function hTuer03_AnyClick()
{
	if (any_click_move(60, 135, eDirectionLeft))
	{
		if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Das ist das Klassenzimmer 3.");
		}
		else if (UsedAction(eActUseInventory))
		{
			if ( player.ActiveInventory == iSchluesselKlasse || player.ActiveInventory == iSchluesselTrophy )
			{
			  player.Say("Dieser Schlüssel passt nicht.");
			}
			else
			{
			  player.Say("Sieht das etwa wie ein Schlüssel aus?");
			}
		}
		//else if ( any_click_on_door (6, oTuer03, 80, 130, eDirectionLeft, 40, 285, 110, eDirectionLeft) )
		else if ( Door[eDoorNumKlassenzimmer3].Click() )
		{
		}
		else Unhandled();
	}
}

function hTuer02_AnyClick()
{
	return Tuer(222, 100, eDirectionRight);
}

function hTuer04_AnyClick()
{
	return Tuer(287, 130, eDirectionRight);
}

function hGang_AnyClick()
{
	if (any_click_move(190, 85, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
			Wait(5);
			player.ChangeRoom(30, 205, 110, eDirectionDown);
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da geht es nach draußen.");
		}
		else Unhandled();
	}
}

function hGangWeiter_AnyClick()
{
	if (any_click_move(190, 140, eDirectionDown))
	{
		if (UsedAction(eActWalkTo))
		{
			Wait(5);
			player.ChangeRoom(32, 0, 130, eDirectionRight);
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Da geht es den Gang entlang.");
		}
		else Unhandled();
	}
}
/****************************
*   Objekt-Funktionen
****************************/



/****************************
*   Hotspot-Funktionen
****************************/
function hLuftschacht_AnyClick()
{
	if (any_click_move(220, 90, eDirectionRight))
	{
		if (UsedAction(eActWalkTo))
		{
		//	Wait(5);
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Ein Lüftungsschacht.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Das Gitter geht nicht ab.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Das Gitter ist im Weg.");
		}
		else if (UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("Der ist fest verschlossen.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Der ist doch schon zu.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Das bringt mich nicht weiter.");
		}
		else if (UsedAction(eActUseInventory))
		{
			player.Say("Damit bekomme ich ihn auch nicht auf.");
		}
		else Unhandled();
	}
}


/****************************
*   Regionen-Funktionen
****************************/