room16.asc

// Vor dem Präsidium (Police Molest)
#define WAIT_INVENTORY 10

/****************************
*   Raum-Funktionen
****************************/
function room_FirstLoad()
{
	String seperator = String.Format("\\ **** Vor dem Präsidium");
#ifdef STARTERPACK_INTRO
	StartCutscene(eSkipESCOrRightButton);  
		Wait (30);
		player.Say("Oh, Sie sind das.");
		player.Say("*grmpf*");
		Wait (40);
		player.Say("Gehen Sie weiter, hier gibt es nichts zu sehen!");
		Wait (40);
		
		Display("Bitte etwas freundlicher, Officer Hobbes!");
		
		player.Say("*grummel*");
		player.Say("Herzlich willkommen zum ['POLICE MOLEST' Starterpack.");
		player.Say("Es gibt hier viel zu entdecken.");
		player.Say("Hinter mir ist das Polizeirevier, erstmals mit Zugang zum 1. Stockwerk.");
		player.Say("Der Fahrstuhlschlüssel sollte immer im Inventar sein.");
		player.Say("Ausserdem gibt's auf Wunsch nun ein Sierra-Style-Punkte-System.");
		gScore.Visible = true;
		PlaySound(107);
		Wait(50);
		player.Say("Das neue Sierra-Style-Textbox Element kennen Sie ja schon.");

		Display("Ach was.");

		player.Say("Zu meiner Rechten ist das Justizgebäude.");
		player.Say("Und zu meiner Linken ist der Parkplatz.");
		player.Say("Mit meinem Streifenwagen können bereits 3 Locations angefahren werden.");
		player.Say("Machen Sie was daraus!");
	EndCutscene();
#endif

	i_GuiSet(true, true); // Gui gAction, GMaingui und Mauszeiger an
	
	StartCutscene(eSkipESCOrRightButton);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iPistole);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iSchlagstock);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iHandschellen);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iFunkgeraet);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iTaschenlampe);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iNotizblock);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iFahrzeugschluessel);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iLeuchtstaebe);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iPlastiktuete);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iGefaengnissch);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iFahrstuhlsch);
		Wait(WAIT_INVENTORY);
		player.AddInventory(iSchluesselkarte);
	EndCutscene();
}

function room_Load()
{
	StopMusic();
	PlayAmbientSound(1, 108, 150, 0, 0); 
}


/****************************
*   Tür-Hotspot-Funktionen
****************************/



/****************************
*   Objekt-Funktionen
****************************/
function oFahnenmast_AnyClick()
{
	if (any_click_move(34, 137, eDirectionDown))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Ein ganz schön stabiles Ding.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Und was mache ich dann damit?");
			/*
			player.Say("Ok.");
			Wait(5);
			PlaySound(4);
			oFahnenmast.Visible = false;
			Wait(20);
			player.Say("Tja, und jetzt?");
			Wait(5);
			player.Say("Wo hin mit dem Masten?");
			Wait(5);
			player.Say("Ich stelle ihn mal wieder hin.");
			Wait(20);
			PlaySound(43);
			oFahnenmast.Visible = true;
			*/
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Ich könnte ihn blau anmalen.");
		}
		else if (UsedAction(eActOpen) || UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Ich kann nur eine Fahne hoch ziehen, oder eine runter holen.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Der ist aber wirklich mal stabil.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Das ist keine Fahne.");
		}
		else Unhandled();
	}
}


/****************************
*   Hotspot-Funktionen
****************************/
function hEingang_AnyClick()
{
	if (any_click_move(168, 132, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
			Wait(5);
			player.ChangeRoom(17, 314, 134, eDirectionLeft);
		}
		else if (UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("Die Tür ist doch schon auf.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Die Tür bleibt tagsüber immer auf.");
		}
		else Unhandled();
	}
}

function hWappen_AnyClick()
{
	if (any_click_move(123, 134, eDirectionUp))
	{
		if (UsedAction(eActWalkTo))
		{
		}
		else if (UsedAction(eActLookAt))
		{
			Wait(5);
			player.Say("Das Motto der Polizei.");
		}
		else if (UsedAction(eActPickUp))
		{
			Wait(5);
			player.Say("Dann kann ich gleich selber in die Zelle gehen.");
		}
		else if (UsedAction(eActUse))
		{
			Wait(5);
			player.Say("Ich hab's mir sicherheitshalber mal gemerkt.");
		}
		else if (UsedAction(eActOpen))
		{
			Wait(5);
			player.Say("Das Wappen mit dem Schriftzug ist in das Glas graviert.");
		}
		else if (UsedAction(eActClose))
		{
			Wait(5);
			player.Say("Nette Idee.");
		}
		else if (UsedAction(eActPull) || UsedAction(eActPush))
		{
			Wait(5);
			player.Say("Vielleicht Morgen.");
		}
		else if (UsedAction(eActUseInventory))
		{
			Wait(5);
			player.Say("Damit klappt's nicht.");
		}
		else Unhandled();
	}
}

function hParkplatz_AnyClick()
{
	if (any_click_move(0, 132, eDirectionLeft))
	{
		if (UsedAction(eActWalkTo))
		{
			Wait(5);
			player.ChangeRoom(40, 307, 132, eDirectionLeft);
		}
	}
}

function hAndereStrasse_AnyClick()
{
	if (any_click_move(318, 132, eDirectionRight))
	{
		if (UsedAction(eActWalkTo))
		{
			Wait(5);
			player.ChangeRoom(6, 24, 132, eDirectionRight);
		}
	}
}


/****************************
*   Regionen-Funktionen
****************************/