kts

build.gradle.kts

@@ -0,0 +1,58 @@
+plugins {
+	base
+	java
+	idea
+	`maven-publish`
+	alias(libs.plugins.fabric.loom)
+}
+
+group = libs.versions.maven.group.get()
+version = "${libs.versions.minecraft.get()}-${libs.versions.mod.get()}"
+
+base {
+	archivesName.set(libs.versions.archives.name)
+}
+
+repositories {
+	mavenCentral()
+}
+
+dependencies {
+	minecraft(libs.minecraft)
+	mappings(libs.yarn)
+	modImplementation(libs.bundles.fabric)
+}
+
+java {
+	sourceCompatibility = JavaVersion.VERSION_17
+	targetCompatibility = JavaVersion.VERSION_17
+
+	withSourcesJar()
+}
+
+tasks {
+	processResources {
+		inputs.property("version", libs.versions.mod.get())
+
+		filesMatching("fabric.mod.json") {
+			expand(mapOf("version" to libs.versions.mod.get()))
+		}
+	}
+
+	jar {
+		from("LICENSE") {
+			rename { "${it}_${base.archivesName}" }
+		}
+	}
+}
+
+publishing {
+	publications {
+		create<MavenPublication>("mavenJava") {
+			from(components["java"])
+		}
+	}
+
+	repositories {
+	}
+}

gradle/libs.versions.toml

@@ -0,0 +1,22 @@
+[versions]
+maven-group = "net.krlite"
+archives-name = "taptab"
+mod = "3.2.0"
+
+minecraft = "1.20"
+yarn = "1.20+build.1"
+fabric-loader = "0.15.7"
+fabric-api = "0.83.0+1.20"
+fabric-loom = "1.5-SNAPSHOT"
+
+[libraries]
+minecraft = { group = "com.mojang", name = "minecraft", version.ref = "minecraft" }
+yarn = { group = "net.fabricmc", name = "yarn", version.ref = "yarn" }
+fabric-loader = { group = "net.fabricmc", name = "fabric-loader", version.ref = "fabric-loader" }
+fabric-api = { group = "net.fabricmc.fabric-api", name = "fabric-api", version.ref = "fabric-api" }
+
+[plugins]
+fabric-loom = { id = "fabric-loom", version.ref = "fabric-loom" }
+
+[bundles]
+fabric = ["fabric-loader", "fabric-api"]

settings.gradle → settings.gradle.kts

@@ -1,8 +1,8 @@
 pluginManagement {
     repositories {
         maven {
-            name = 'Fabric'
-            url = 'https://maven.fabricmc.net/'
+            name = "Fabric"
+            url = uri("https://maven.fabricmc.net/")
         }
         mavenCentral()
         gradlePluginPortal()