build.gradle

plugins {
    id 'org.moddingx.modgradle.meta' version '5.0.2'
}

repositories {
    maven {
        url = "https://modmaven.dev/"
    }
}

var dev = System.getenv('IS_DEV')?.toBoolean() ?: false
var baseVersion = '21.1'
var libxVersion = '1.21.1-6.0.0'
var jeiVersion = '19.21.0.247'

mod.configure {
    modid 'morevanillalib'
    group 'de.melanx'
    versioning {
        if (dev) {
            def gitCommitHash = ['git', 'rev-parse', 'HEAD'].execute().text.trim()
            constant baseVersion + (gitCommitHash ? "-${gitCommitHash}" : '')
        } else {
            base baseVersion
            maven 'https://maven.melanx.de/release'
        }
    }

    neoforge project.hasProperty('neo_version') ? project.neo_version : "${baseVersion}.118"

    license 'The Apache License, Version 2.0'
    github 'ChaoticTrials/MoreVanillaLib'

    artifacts {
        sources {
            publishToRepositories()
        }
    }

    changelog {
        def lines = defaultChangelog.toString().split('\n')
        def filteredChangelog = lines.findAll { !it.startsWith('- [meta]') }.join('\n')

        return filteredChangelog
    }


    publishing {
        maven {
            name 'melanx'
            url 'https://maven.melanx.de/release'
            credentials(PasswordCredentials)
        }
    }

    upload {
        all {
            type 'release'
            require 'libx'
            optional 'jei'
        }
        curseforge {
            projectId 367254
        }
        modrinth {
            projectId 'CtNNDljK'
        }
    }
}

dependencies {
    annotationProcessor "org.moddingx:LibX:${libxVersion}"

    implementation "org.moddingx:LibX:${libxVersion}"
    implementation "mezz.jei:jei-1.${baseVersion}-neoforge:${jeiVersion}"
}