esp32 cam and ST7789V

[Krumpytail]

I've been trying to figure out how to get the ESP32 cam selfie project to work. I've got most of it. I can't seem to fill the screen with the image from the camera, I've gone over everything I can think of.

Examples work fine. They fill the tft completely the way they should, but when I use the camera I think I'm only getting half or a quarter of the image and I can't move it very far before it disappears. Seems that maybe the image has a center pivot point attached to the corner of the tft.

`

#include "esp_camera.h"
#include "Arduino.h"
#include "fd_forward.h"

#include <SPI.h>
#include <TFT_eSPI.h>
TFT_eSPI tft = TFT_eSPI();
#include <TFT_eFEX.h>
TFT_eFEX fex = TFT_eFEX(&tft);
TFT_eSprite spr = TFT_eSprite(&tft);

String filelist;
camera_fb_t * fb = NULL;
String incoming;
long current_millis;
long last_capture_millis = 0;
static esp_err_t cam_err;
static esp_err_t card_err;
char strftime_buf[64];
long file_number = 0;

// CAMERA_MODEL_AI_THINKER
#define PWDN_GPIO_NUM 32
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 0
#define SIOD_GPIO_NUM 26
#define SIOC_GPIO_NUM 27
#define Y9_GPIO_NUM 35
#define Y8_GPIO_NUM 34
#define Y7_GPIO_NUM 39
#define Y6_GPIO_NUM 36
#define Y5_GPIO_NUM 21
#define Y4_GPIO_NUM 19
#define Y3_GPIO_NUM 18
#define Y2_GPIO_NUM 5
#define VSYNC_GPIO_NUM 25
#define HREF_GPIO_NUM 23
#define PCLK_GPIO_NUM 22

static inline mtmn_config_t app_mtmn_config()
{
mtmn_config_t mtmn_config = {0};
mtmn_config.type = FAST;
mtmn_config.min_face = 60; // 80 default
mtmn_config.pyramid = 0.707;
mtmn_config.pyramid_times = 4;
mtmn_config.p_threshold.score = 0.6;
mtmn_config.p_threshold.nms = 0.7;
mtmn_config.p_threshold.candidate_number = 20;
mtmn_config.r_threshold.score = 0.7;
mtmn_config.r_threshold.nms = 0.7;
mtmn_config.r_threshold.candidate_number = 10;
mtmn_config.o_threshold.score = 0.7;
mtmn_config.o_threshold.nms = 0.7;
mtmn_config.o_threshold.candidate_number = 1;
return mtmn_config;
}
mtmn_config_t mtmn_config = app_mtmn_config();

void setup() {
Serial.begin(115200);

pinMode(4, OUTPUT);// initialize io4 as an output for LED flash.
digitalWrite(4, LOW); // flash off/

tft.begin();
spr.createSprite(tft.width()/2,tft.height()/2);

tft.setRotation(1); // 0 & 2 Portrait. 1 & 3 landscape
tft.fillScreen(TFT_BLACK);
tft.setViewport(2, 2, 236, 131, true);
tft.frameViewport(TFT_WHITE, -1);
tft.setTextColor(TFT_WHITE);
tft.setTextSize(1);

delay(100);

camera_config_t config;
config.ledc_channel = LEDC_CHANNEL_0;
config.ledc_timer = LEDC_TIMER_0;
config.pin_d0 = Y2_GPIO_NUM;
config.pin_d1 = Y3_GPIO_NUM;
config.pin_d2 = Y4_GPIO_NUM;
config.pin_d3 = Y5_GPIO_NUM;
config.pin_d4 = Y6_GPIO_NUM;
config.pin_d5 = Y7_GPIO_NUM;
config.pin_d6 = Y8_GPIO_NUM;
config.pin_d7 = Y9_GPIO_NUM;
config.pin_xclk = XCLK_GPIO_NUM;
config.pin_pclk = PCLK_GPIO_NUM;
config.pin_vsync = VSYNC_GPIO_NUM;
config.pin_href = HREF_GPIO_NUM;
config.pin_sscb_sda = SIOD_GPIO_NUM;
config.pin_sscb_scl = SIOC_GPIO_NUM;
config.pin_pwdn = PWDN_GPIO_NUM;
config.pin_reset = RESET_GPIO_NUM;
config.xclk_freq_hz = 10000000;
config.pixel_format = PIXFORMAT_JPEG;

//init with high specs to pre-allocate larger buffers
if (psramFound()) {
config.frame_size = FRAMESIZE_UXGA;
config.jpeg_quality = 10;
config.fb_count = 2;
} else {
config.frame_size = FRAMESIZE_SVGA;
config.jpeg_quality = 12;
config.fb_count = 1;
}

// camera init
cam_err = esp_camera_init(&config);
if (cam_err != ESP_OK) {
Serial.printf("Camera init failed with error 0x%x", cam_err);
return;
}
config.jpeg_quality = 10;
sensor_t * s = esp_camera_sensor_get();
s->set_framesize(s, FRAMESIZE_HQVGA); //FRAMESIZE_QVGA);
s->set_vflip(s, 1);

if (SPIFFS.begin()){
Serial.println(F("done."));
}else{
Serial.println(F("fail."));
}
Serial.println("\r\nInitialisation done.");
fex.listSPIFFS(); // Lists the files so you can see what is in the SPIFFS

}

String filelist_spiffs()
{

filelist = "";
fs::File root = SPIFFS.open("/");

fs::File file = root.openNextFile();
while (file) {
String fileName = file.name();
filelist = filelist + fileName;
file = root.openNextFile();
}
Serial.println(filelist);
return filelist;
}

uint8_t scale = (uint8_t)JPEG_DIV_NONE;
//uint8_t scale = (uint8_t)JPEG_DIV_2;

void loop() {
camera_fb_t *fb = NULL;
esp_err_t res = ESP_OK;
fb = esp_camera_fb_get();
if(!fb){
Serial.println("Camera capture failed");
esp_camera_fb_return(fb);
return;
}

size_t fb_len = 0;
if(fb->format != PIXFORMAT_JPEG){
Serial.println("Non-JPEG data not implemented");
return;
}
fex.drawJpg((const uint8_t*)fb->buf, fb->len,0,0,0,0);

esp_camera_fb_return(fb);
}

/*
void loop(){

tft.resetViewport();
fb = esp_camera_fb_get();

//fex.drawJpg((const uint8_t*)fb->buf, fb->len,100,65,240,135,0,0,(jpeg_div_t)scale);
//fex.drawJpg((const uint8_t*)fb->buf, fb->len,100,63,0,0,0,0,(jpeg_div_t)scale); //div2
fex.drawJpg((const uint8_t*)fb->buf, fb->len,tft.getViewportX(),tft.getViewportY(),0,0,0,0,(jpeg_div_t)scale); //divNONE
//70,35,240,135,0,0,

esp_camera_fb_return(fb);
fb = NULL;

}*/`

[Bodmer]

This is probably related to the issue #873 which is under investigation.

[Bodmer]

Issue #873 has been resolved but is not the cause of the problem you are experiencing. I will investigate further.

[Krumpytail]

Cool, thanks.

[Bodmer]

The problem is in the TFT_eFEX library, when it decodes the jpeg it appears to be corrupting the offset value for some reason.

I would use my TJpg_Decoder and do not load TFT_eFEX. There are examples with that library. The key additions to your sketch are a rendering function:

bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t* bitmap)
{
   // Stop further decoding as image is running off bottom of screen
  if ( y >= tft.height() ) return 0;

  // This function will clip the image block rendering automatically at the TFT boundaries
  tft.pushImage(x, y, w, h, bitmap);

  // Return 1 to decode next block
  return 1;
}

A few lines in setup:

  TJpgDec.setSwapBytes(true);
  TJpgDec.setJpgScale(1);
  TJpgDec.setCallback(tft_output);

Then this function to render the Jpeg:

drawJpg(int32_t x, int32_t y, const uint8_t array[], uint32_t  array_size);

[Krumpytail]

Thanks, I'm going to try to do all that.

[Krumpytail]

Thank you again, now I'm having difficulty getting that drawJpg(... function to work.
It compiles as long as I don't add it, but I'm pretty sure it's important.
I've added all the rest and added TJpg_Decoder to my library. Still kinda new to all this.
I'm going to go back to looking at the examples. Part of my issue is that
the examples are using image names and mine is coming from the sensor and I'm
still trying to wrap my brain around how that all works.

[Bodmer]

I think this should work as a replacement line:

drawJpg(tft.getViewportX(), tft.getViewportY(), (const uint8_t*)fb->buf, fb->len);

Note: I had to edit this line a few times as I tried to create this message on a tiny phone screen!

[Krumpytail]

It works, thank you so much.