Star Wars day ascii animation

[delhoume]

https://github.com/gotohellmann/AsciiWars

I modified it little bit to use sprite (for each text line) but it should be easy to use full screen double buffer sprite as it is 2 or 4 colour only.

The author has a patched TFT_eSPI but I think this is not neccessary at all when using sprites.

[Bodmer]

Thanks for posting this. Yes, sprites would be better.

I did not see a sprite version posted, but the changes to the main sketch tab are simple and a single line sprite only takes a few kbytes.

Here is my version of the main sketch tab which works fine on an ESP32:

/*******************************************************

                    AsciiWars

 code by        F. Hellmann  <www.gotohellmann.com>
 animation by   S. Jansen    <www.asciimation.co.nz>
 font by        S. Weber     <https://blogfonts.com/picopixel.font>

 adaption to use a sprite for flicker free animation by Bodmer

 This sketch is playing back an ASCII animation of 
 StarWars on a LCD Screen.

 Platform: Arduino on ESP32
           ILI9341 240x320 Pixel RGB LCD Display
          
 *******************************************************/

// TFT Libraries
#include "SPI.h"
#include <TFT_eSPI.h>
#include "iliPicopixel.h"

// SPIFFS filesystem
#include <FS.h>

fs::File ani;           // File handle for animation

int wait;               // How long to wait til next frame
String line;            // Current line in animation file
char padded[80];        // Format String into
int frame;              // current frame

#define DELAY 60
#define DARKGREEN 0x01E0 

TFT_eSPI tft = TFT_eSPI();
TFT_eSprite spr = TFT_eSprite(&tft);

void setup() {
  Serial.begin(9600);
  Serial.println("AsciiWars V0.1"); 

  // LCD Module setup
  // we use an ILI9341 240x320 display
  tft.begin();
  Serial.println(F("TFT setup done."));
  tft.setRotation(1);

  // Create a sprite using the newly rotated screen width and font height
  spr.createSprite(tft.width(), 7);

  tft.fillScreen(TFT_BLACK);
  tft.setCursor(108, 16);
  tft.setTextColor(DARKGREEN, TFT_BLACK);
  tft.setTextSize(2);
  tft.println("AsciiWars");
  tft.setTextSize(1);
  tft.setCursor(20, 220);
  tft.println("Animation: Simon Jansen - Code: Frank Hellmann");

  // SPIFFS Filesystem setup
  SPIFFS.begin();

  //------------------------ Formatting -------------------------
  // Comment in to format a blank WEMOS Module SPIFFS with this.
  //                  !!! Do this only once !!! ;-)
  /*
  Serial.println("Please wait 30 secs for SPIFFS to be formatted");
  SPIFFS.format();
  Serial.println("SPIFFS formatted. Don't forget to transfer new files onto it.");
  */

  // Check that our asciimation.txt file is accessible
  Serial.println("Opening asciimation.txt file.");
  ani = SPIFFS.open("/asciimation.txt", "r");
  if (!ani) {
      // Not accessible -> notify and stop.      
      Serial.println("asciimation.txt is missing.");
      tft.setTextColor(TFT_RED, TFT_BLACK);
      tft.setTextSize(1);
      tft.setCursor(40,120);
      tft.println("The asciimation.txt file is missing.");
      tft.setCursor(40,140);
      tft.println("Please upload file via Arduino IDE. ");
      tft.setCursor(40,160);
      tft.println("  System halted and catching fire.  ");
      while(1){
        yield();  // Do nothing and let the watchdog sleep...
      };
  }

  // Cool. Animation is loaded. Let's go...
  Serial.println("asciimation.txt is ready for playback.");

  // Set the font parameters for the sprite
  spr.setFreeFont(&Picopixel);
  spr.setTextSize(1);
  spr.setTextColor(TFT_GREEN, TFT_BLACK);
}

void loop(void) {
  frame=0;
  // Run Animation
  while ( ani.available() ){
    line=ani.readStringUntil('\n');      // 1. Line of frame contains the delay
    wait=line.toInt();
    for (int i=1; i<=13; i++){
      // Read line, format  and print it
      line = ani.readStringUntil('\n');
      sprintf(padded, "      %-68s", line.c_str());

      spr.drawString(padded,0,0);  // Draw string to sprite
      spr.pushSprite(0,77+(i*7));  // Plot sprite to TFT
    }
    frame++;
    delay(DELAY*wait);                   // delay between frames 
  }
  // Restart Animation
  ani.seek(0, fs::SeekSet);
  Serial.println("Restart animation.");
}