help modifying BMP_functions to display BMP with 16-bit color RGB555

[galed3e3]

I'd appreciate some pointers for modifying the code excerpt below...beyond the obvious initial check for color depth. I'm not clear on how to modify the padding, lineBuffer, and color conversion code.

(I need to display a BMP that uses RGB555 mode...16 bits...whereas the library's "BMP_functions.ino" only recognizes 24 bit BMP format.)

Thank you.

//if ((read16(bmpFS) == 1) && (read16(bmpFS) == 24) && (read32(bmpFS) == 0)) // <--- original expects 24 bit color depth
    if ((read16(bmpFS) == 1) && (read16(bmpFS) == 16) && (read32(bmpFS) == 0)) // <--- mod by me for 16 bit depth
    {
      y += h - 1;

      bool oldSwapBytes = tft.getSwapBytes();
      tft.setSwapBytes(true);
      bmpFS.seek(seekOffset);

      uint16_t padding = (4 - ((w * 3) & 3)) & 3;
      uint8_t lineBuffer[w * 3 + padding];

      for (row = 0; row < h; row++) {
        
        bmpFS.read(lineBuffer, sizeof(lineBuffer));
        uint8_t*  bptr = lineBuffer;
        uint16_t* tptr = (uint16_t*)lineBuffer;
        
        // Convert 24 to 16 bit colours.... <---- not needed?...already 16 bits
        for (uint16_t col = 0; col < w; col++)
        {
          b = *bptr++;
          g = *bptr++;
          r = *bptr++;
          *tptr++ = ((r & 0xF8) << 8) | ((g & 0xFC) << 3) | (b >> 3);
        }

        // Push the pixel row to screen, pushImage will crop the line if needed
        // y is decremented as the BMP image is drawn bottom up
        tft.pushImage(x, y--, w, 1, (uint16_t*)lineBuffer);
      }
      tft.setSwapBytes(oldSwapBytes);
      Serial.print("Loaded in "); Serial.print(millis() - startTime);
      Serial.println(" ms");
    }

PS: FWIW, TFT_eSPI worked with the Adafruit ESP32 Feather and the Adafruit 3.5" TFT 320x480 w/ HXD8357D (their product ID 2050) with the following user_setup. I successfully ran the Colour_Test and TFT_SPIFFS_BMP examples (I converted the latter to littleFS).

#define HX8357D_DRIVER
#define TFT_MISO 19
#define TFT_MOSI 18
#define TFT_SCLK 5
#define TFT_CS   26  // Chip select control pin
#define TFT_DC   25  // Data Command control pin
#define SPI_FREQUENCY  20000000

[Bodmer]

Can you provide an image and the full/simplified sketch you have and I will see if I can get it to work.

[galed3e3]

Sure thing - thank you. Here's a zipped BMP with 16-bit 555 depth (drag/drop of the BMP itself didn't work...format not recognized).
graph20190626.zip

My test sketch is the following, together with your BMP_functions.ino in separate tab:

#include <Arduino.h>
#include "FS.h"
#include <LITTLEFS.h>
#include <TFT_eSPI.h>  // tested w/ v.2.3.59 and .60;  don't forget to save user_setup *before* updating
TFT_eSPI tft = TFT_eSPI();

void setup()
{
  Serial.begin(115200);
  Serial.println("starting LitFS");
  if (!LITTLEFS.begin()) {
    Serial.println("LitFS mount failed");
    return;
  }
  tft.begin();
  tft.setRotation(3);  // 0 & 2 Portrait. 1 & 3 landscape
  drawBmp("/graph.bmp", 0, 0); // file in the zip was renamed to graph.bmp
}

void loop() {
}

Also, in BMP_functions.ino, I changed

bmpFS = SPIFFS.open(filename, "r");
to
bmpFS = LITTLEFS.open(filename, "r");

Of course it fails with "BMP format not recognized" since the helper only takes 24-bit color (it works with the parrot.bmp from the example).

If I was sufficiently skilled, I would have modified BMP_functions.ino to take either 24-bit or 16-bit and submitted a PR, but sadly...

[Bodmer]

This should work (note r,g,b and new c variables are now 16 bit):

void drawBmp(const char *filename, int16_t x, int16_t y) {

  if ((x >= tft.width()) || (y >= tft.height())) return;

  fs::File bmpFS;

  // Open requested file on SD card
  bmpFS = SPIFFS.open(filename, "r");

  if (!bmpFS)
  {
    Serial.print("File not found");
    return;
  }

  uint32_t seekOffset;
  uint16_t w, h, row, col;
  uint16_t  r, g, b, c;

  uint32_t startTime = millis();

  if (read16(bmpFS) == 0x4D42)
  {
    read32(bmpFS);
    read32(bmpFS);
    seekOffset = read32(bmpFS);
    read32(bmpFS);
    w = read32(bmpFS);
    h = read32(bmpFS);

    if ((read16(bmpFS) == 1) && (read16(bmpFS) == 16) && (read32(bmpFS) == 0))
    {
      y += h - 1;

      bool oldSwapBytes = tft.getSwapBytes();
      tft.setSwapBytes(true);
      bmpFS.seek(seekOffset);

      uint16_t padding = (4 - ((w * 3) & 3)) & 3;
      uint8_t lineBuffer[w * 2 + padding];

      for (row = 0; row < h; row++) {
        
        bmpFS.read(lineBuffer, sizeof(lineBuffer));
        uint8_t*  bptr = lineBuffer;
        uint16_t* tptr = (uint16_t*)lineBuffer;
        // Convert 24 to 16 bit colours
        for (uint16_t col = 0; col < w; col++)
        {
          c = *bptr++;          // LS byte
          b = (c & 0x1F);       // 5 blue bits
          g = (c & 0xE0) << 1;  // 3 LSB of 5 green bits

          c = *bptr++;          // MS byte
          r = (c & 0x7C) << 9;  // 5 red bits
          g = g | ((c & 0x03) << 9) | ((c & 0x02) << 4); // 2 MSB of 5 green bits and copy MS bit to 6th green bit
          *tptr++ = r | g | b;
        }

        // Push the pixel row to screen, pushImage will crop the line if needed
        // y is decremented as the BMP image is drawn bottom up
        tft.pushImage(x, y--, w, 1, (uint16_t*)lineBuffer);
      }
      tft.setSwapBytes(oldSwapBytes);
      Serial.print("Loaded in "); Serial.print(millis() - startTime);
      Serial.println(" ms");
    }
    else Serial.println("BMP format not recognized.");
  }
  bmpFS.close();
}

[galed3e3]

Thanks! I'll try it later this weekend.

[galed3e3]

It worked! Thank you very much.

I added it to BMP_functions...named it "draw16bmp" and changed the original to "draw24bmp".

Also, to get it to work with LittleFS, I changed

bmpFS = SPIFFS.open(filename, "r");

to

bmpFS = LITTLEFS.open(filename, "r");